dsytrs2.f

*> \brief \b DSYTRS2
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download DSYTRS2 + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dsytrs2.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dsytrs2.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dsytrs2.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE DSYTRS2( UPLO, N, NRHS, A, LDA, IPIV, B, LDB,
*                           WORK, INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            INFO, LDA, LDB, N, NRHS
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * )
*       DOUBLE PRECISION   A( LDA, * ), B( LDB, * ), WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DSYTRS2 solves a system of linear equations A*X = B with a real
*> symmetric matrix A using the factorization A = U*D*U**T or
*> A = L*D*L**T computed by DSYTRF and converted by DSYCONV.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the details of the factorization are stored
*>          as an upper or lower triangular matrix.
*>          = 'U':  Upper triangular, form is A = U*D*U**T;
*>          = 'L':  Lower triangular, form is A = L*D*L**T.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand sides, i.e., the number of columns
*>          of the matrix B.  NRHS >= 0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension (LDA,N)
*>          The block diagonal matrix D and the multipliers used to
*>          obtain the factor U or L as computed by DSYTRF.
*>          Note that A is input / output. This might be counter-intuitive,
*>          and one may think that A is input only. A is input / output. This
*>          is because, at the start of the subroutine, we permute A in a
*>          "better" form and then we permute A back to its original form at
*>          the end.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in] IPIV
*> \verbatim
*>          IPIV is INTEGER array, dimension (N)
*>          Details of the interchanges and the block structure of D
*>          as determined by DSYTRF.
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is DOUBLE PRECISION array, dimension (LDB,NRHS)
*>          On entry, the right hand side matrix B.
*>          On exit, the solution matrix X.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B.  LDB >= max(1,N).
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (N)
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup hetrs2
*
*  =====================================================================
      SUBROUTINE dsytrs2( UPLO, N, NRHS, A, LDA, IPIV, B, LDB,
     $                    WORK, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, LDB, N, NRHS
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      DOUBLE PRECISION   A( lda, * ), B( ldb, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE
      parameter( one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            I, IINFO, J, K, KP
      DOUBLE PRECISION   AK, AKM1, AKM1K, BK, BKM1, DENOM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           dscal, dsyconv, dswap, dtrsm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -8
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DSYTRS2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 )
     $   RETURN
*
*     Convert A
*
      CALL dsyconv( uplo, 'C', n, a, lda, ipiv, work, iinfo )
*
      IF( upper ) THEN
*
*        Solve A*X = B, where A = U*D*U**T.
*
*       P**T * B
        k=n
        DO WHILE ( k .GE. 1 )
         IF( ipiv( k ).GT.0 ) THEN
*           1 x 1 diagonal block
*           Interchange rows K and IPIV(K).
            kp = ipiv( k )
            IF( kp.NE.k )
     $         CALL dswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            k=k-1
         ELSE
*           2 x 2 diagonal block
*           Interchange rows K-1 and -IPIV(K).
            kp = -ipiv( k )
            IF( kp.EQ.-ipiv( k-1 ) )
     $         CALL dswap( nrhs, b( k-1, 1 ), ldb, b( kp, 1 ), ldb )
            k=k-2
         END IF
        END DO
*
*  Compute (U \P**T * B) -> B    [ (U \P**T * B) ]
*
        CALL dtrsm('L','U','N','U',n,nrhs,one,a,lda,b,ldb)
*
*  Compute D \ B -> B   [ D \ (U \P**T * B) ]
*
         i=n
         DO WHILE ( i .GE. 1 )
            IF( ipiv(i) .GT. 0 ) THEN
              CALL dscal( nrhs, one / a( i, i ), b( i, 1 ), ldb )
            ELSEIF ( i .GT. 1) THEN
               IF ( ipiv(i-1) .EQ. ipiv(i) ) THEN
                  akm1k = work(i)
                  akm1 = a( i-1, i-1 ) / akm1k
                  ak = a( i, i ) / akm1k
                  denom = akm1*ak - one
                  DO 15 j = 1, nrhs
                     bkm1 = b( i-1, j ) / akm1k
                     bk = b( i, j ) / akm1k
                     b( i-1, j ) = ( ak*bkm1-bk ) / denom
                     b( i, j ) = ( akm1*bk-bkm1 ) / denom
 15              CONTINUE
               i = i - 1
               ENDIF
            ENDIF
            i = i - 1
         END DO
*
*      Compute (U**T \ B) -> B   [ U**T \ (D \ (U \P**T * B) ) ]
*
         CALL dtrsm('L','U','T','U',n,nrhs,one,a,lda,b,ldb)
*
*       P * B  [ P * (U**T \ (D \ (U \P**T * B) )) ]
*
        k=1
        DO WHILE ( k .LE. n )
         IF( ipiv( k ).GT.0 ) THEN
*           1 x 1 diagonal block
*           Interchange rows K and IPIV(K).
            kp = ipiv( k )
            IF( kp.NE.k )
     $         CALL dswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            k=k+1
         ELSE
*           2 x 2 diagonal block
*           Interchange rows K-1 and -IPIV(K).
            kp = -ipiv( k )
            IF( k .LT. n .AND. kp.EQ.-ipiv( k+1 ) )
     $         CALL dswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            k=k+2
         ENDIF
        END DO
*
      ELSE
*
*        Solve A*X = B, where A = L*D*L**T.
*
*       P**T * B
        k=1
        DO WHILE ( k .LE. n )
         IF( ipiv( k ).GT.0 ) THEN
*           1 x 1 diagonal block
*           Interchange rows K and IPIV(K).
            kp = ipiv( k )
            IF( kp.NE.k )
     $         CALL dswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            k=k+1
         ELSE
*           2 x 2 diagonal block
*           Interchange rows K and -IPIV(K+1).
            kp = -ipiv( k+1 )
            IF( kp.EQ.-ipiv( k ) )
     $         CALL dswap( nrhs, b( k+1, 1 ), ldb, b( kp, 1 ), ldb )
            k=k+2
         ENDIF
        END DO
*
*  Compute (L \P**T * B) -> B    [ (L \P**T * B) ]
*
        CALL dtrsm('L','L','N','U',n,nrhs,one,a,lda,b,ldb)
*
*  Compute D \ B -> B   [ D \ (L \P**T * B) ]
*
         i=1
         DO WHILE ( i .LE. n )
            IF( ipiv(i) .GT. 0 ) THEN
              CALL dscal( nrhs, one / a( i, i ), b( i, 1 ), ldb )
            ELSE
                  akm1k = work(i)
                  akm1 = a( i, i ) / akm1k
                  ak = a( i+1, i+1 ) / akm1k
                  denom = akm1*ak - one
                  DO 25 j = 1, nrhs
                     bkm1 = b( i, j ) / akm1k
                     bk = b( i+1, j ) / akm1k
                     b( i, j ) = ( ak*bkm1-bk ) / denom
                     b( i+1, j ) = ( akm1*bk-bkm1 ) / denom
 25              CONTINUE
                  i = i + 1
            ENDIF
            i = i + 1
         END DO
*
*  Compute (L**T \ B) -> B   [ L**T \ (D \ (L \P**T * B) ) ]
*
        CALL dtrsm('L','L','T','U',n,nrhs,one,a,lda,b,ldb)
*
*       P * B  [ P * (L**T \ (D \ (L \P**T * B) )) ]
*
        k=n
        DO WHILE ( k .GE. 1 )
         IF( ipiv( k ).GT.0 ) THEN
*           1 x 1 diagonal block
*           Interchange rows K and IPIV(K).
            kp = ipiv( k )
            IF( kp.NE.k )
     $         CALL dswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            k=k-1
         ELSE
*           2 x 2 diagonal block
*           Interchange rows K-1 and -IPIV(K).
            kp = -ipiv( k )
            IF( k.GT.1 .AND. kp.EQ.-ipiv( k-1 ) )
     $         CALL dswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
            k=k-2
         ENDIF
        END DO
*
      END IF
*
*     Revert A
*
      CALL dsyconv( uplo, 'R', n, a, lda, ipiv, work, iinfo )
*
      RETURN
*
*     End of DSYTRS2
*
      END