dtpmqrt.f

*> \brief \b DTPMQRT
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download DTPMQRT + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dtpmqrt.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dtpmqrt.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dtpmqrt.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE DTPMQRT( SIDE, TRANS, M, N, K, L, NB, V, LDV, T, LDT,
*                           A, LDA, B, LDB, WORK, INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER SIDE, TRANS
*       INTEGER   INFO, K, LDV, LDA, LDB, M, N, L, NB, LDT
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   V( LDV, * ), A( LDA, * ), B( LDB, * ),
*      $                   T( LDT, * ), WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DTPMQRT applies a real orthogonal matrix Q obtained from a
*> "triangular-pentagonal" real block reflector H to a general
*> real matrix C, which consists of two blocks A and B.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] SIDE
*> \verbatim
*>          SIDE is CHARACTER*1
*>          = 'L': apply Q or Q**T from the Left;
*>          = 'R': apply Q or Q**T from the Right.
*> \endverbatim
*>
*> \param[in] TRANS
*> \verbatim
*>          TRANS is CHARACTER*1
*>          = 'N':  No transpose, apply Q;
*>          = 'T':  Transpose, apply Q**T.
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix B. M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix B. N >= 0.
*> \endverbatim
*>
*> \param[in] K
*> \verbatim
*>          K is INTEGER
*>          The number of elementary reflectors whose product defines
*>          the matrix Q.
*> \endverbatim
*>
*> \param[in] L
*> \verbatim
*>          L is INTEGER
*>          The order of the trapezoidal part of V.
*>          K >= L >= 0.  See Further Details.
*> \endverbatim
*>
*> \param[in] NB
*> \verbatim
*>          NB is INTEGER
*>          The block size used for the storage of T.  K >= NB >= 1.
*>          This must be the same value of NB used to generate T
*>          in CTPQRT.
*> \endverbatim
*>
*> \param[in] V
*> \verbatim
*>          V is DOUBLE PRECISION array, dimension (LDV,K)
*>          The i-th column must contain the vector which defines the
*>          elementary reflector H(i), for i = 1,2,...,k, as returned by
*>          CTPQRT in B.  See Further Details.
*> \endverbatim
*>
*> \param[in] LDV
*> \verbatim
*>          LDV is INTEGER
*>          The leading dimension of the array V.
*>          If SIDE = 'L', LDV >= max(1,M);
*>          if SIDE = 'R', LDV >= max(1,N).
*> \endverbatim
*>
*> \param[in] T
*> \verbatim
*>          T is DOUBLE PRECISION array, dimension (LDT,K)
*>          The upper triangular factors of the block reflectors
*>          as returned by CTPQRT, stored as a NB-by-K matrix.
*> \endverbatim
*>
*> \param[in] LDT
*> \verbatim
*>          LDT is INTEGER
*>          The leading dimension of the array T.  LDT >= NB.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension
*>          (LDA,N) if SIDE = 'L' or
*>          (LDA,K) if SIDE = 'R'
*>          On entry, the K-by-N or M-by-K matrix A.
*>          On exit, A is overwritten by the corresponding block of
*>          Q*C or Q**T*C or C*Q or C*Q**T.  See Further Details.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.
*>          If SIDE = 'L', LDC >= max(1,K);
*>          If SIDE = 'R', LDC >= max(1,M).
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is DOUBLE PRECISION array, dimension (LDB,N)
*>          On entry, the M-by-N matrix B.
*>          On exit, B is overwritten by the corresponding block of
*>          Q*C or Q**T*C or C*Q or C*Q**T.  See Further Details.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B.
*>          LDB >= max(1,M).
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array. The dimension of WORK is
*>           N*NB if SIDE = 'L', or  M*NB if SIDE = 'R'.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup tpmqrt
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*>
*>  The columns of the pentagonal matrix V contain the elementary reflectors
*>  H(1), H(2), ..., H(K); V is composed of a rectangular block V1 and a
*>  trapezoidal block V2:
*>
*>        V = [V1]
*>            [V2].
*>
*>  The size of the trapezoidal block V2 is determined by the parameter L,
*>  where 0 <= L <= K; V2 is upper trapezoidal, consisting of the first L
*>  rows of a K-by-K upper triangular matrix.  If L=K, V2 is upper triangular;
*>  if L=0, there is no trapezoidal block, hence V = V1 is rectangular.
*>
*>  If SIDE = 'L':  C = [A]  where A is K-by-N,  B is M-by-N and V is M-by-K.
*>                      [B]
*>
*>  If SIDE = 'R':  C = [A B]  where A is M-by-K, B is M-by-N and V is N-by-K.
*>
*>  The real orthogonal matrix Q is formed from V and T.
*>
*>  If TRANS='N' and SIDE='L', C is on exit replaced with Q * C.
*>
*>  If TRANS='T' and SIDE='L', C is on exit replaced with Q**T * C.
*>
*>  If TRANS='N' and SIDE='R', C is on exit replaced with C * Q.
*>
*>  If TRANS='T' and SIDE='R', C is on exit replaced with C * Q**T.
*> \endverbatim
*>
*  =====================================================================
      SUBROUTINE dtpmqrt( SIDE, TRANS, M, N, K, L, NB, V, LDV, T, LDT,
     $                    A, LDA, B, LDB, WORK, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER SIDE, TRANS
      INTEGER   INFO, K, LDV, LDA, LDB, M, N, L, NB, LDT
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   V( ldv, * ), A( lda, * ), B( ldb, * ),
     $                   t( ldt, * ), work( * )
*     ..
*
*  =====================================================================
*
*     ..
*     .. Local Scalars ..
      LOGICAL            LEFT, RIGHT, TRAN, NOTRAN
      INTEGER            I, IB, MB, LB, KF, LDAQ, LDVQ
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           dtprfb, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     .. Test the input arguments ..
*
      info   = 0
      left   = lsame( side,  'L' )
      right  = lsame( side,  'R' )
      tran   = lsame( trans, 'T' )
      notran = lsame( trans, 'N' )
*
      IF ( left ) THEN
         ldvq = max( 1, m )
         ldaq = max( 1, k )
      ELSE IF ( right ) THEN
         ldvq = max( 1, n )
         ldaq = max( 1, m )
      END IF
      IF( .NOT.left .AND. .NOT.right ) THEN
         info = -1
      ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
         info = -2
      ELSE IF( m.LT.0 ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( k.LT.0 ) THEN
         info = -5
      ELSE IF( l.LT.0 .OR. l.GT.k ) THEN
         info = -6
      ELSE IF( nb.LT.1 .OR. (nb.GT.k .AND. k.GT.0) ) THEN
         info = -7
      ELSE IF( ldv.LT.ldvq ) THEN
         info = -9
      ELSE IF( ldt.LT.nb ) THEN
         info = -11
      ELSE IF( lda.LT.ldaq ) THEN
         info = -13
      ELSE IF( ldb.LT.max( 1, m ) ) THEN
         info = -15
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DTPMQRT', -info )
         RETURN
      END IF
*
*     .. Quick return if possible ..
*
      IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 ) RETURN
*
      IF( left .AND. tran ) THEN
*
         DO i = 1, k, nb
            ib = min( nb, k-i+1 )
            mb = min( m-l+i+ib-1, m )
            IF( i.GE.l ) THEN
               lb = 0
            ELSE
               lb = mb-m+l-i+1
            END IF
            CALL dtprfb( 'L', 'T', 'F', 'C', mb, n, ib, lb,
     $                   v( 1, i ), ldv, t( 1, i ), ldt,
     $                   a( i, 1 ), lda, b, ldb, work, ib )
         END DO
*
      ELSE IF( right .AND. notran ) THEN
*
         DO i = 1, k, nb
            ib = min( nb, k-i+1 )
            mb = min( n-l+i+ib-1, n )
            IF( i.GE.l ) THEN
               lb = 0
            ELSE
               lb = mb-n+l-i+1
            END IF
            CALL dtprfb( 'R', 'N', 'F', 'C', m, mb, ib, lb,
     $                   v( 1, i ), ldv, t( 1, i ), ldt,
     $                   a( 1, i ), lda, b, ldb, work, m )
         END DO
*
      ELSE IF( left .AND. notran ) THEN
*
         kf = ((k-1)/nb)*nb+1
         DO i = kf, 1, -nb
            ib = min( nb, k-i+1 )
            mb = min( m-l+i+ib-1, m )
            IF( i.GE.l ) THEN
               lb = 0
            ELSE
               lb = mb-m+l-i+1
            END IF
            CALL dtprfb( 'L', 'N', 'F', 'C', mb, n, ib, lb,
     $                   v( 1, i ), ldv, t( 1, i ), ldt,
     $                   a( i, 1 ), lda, b, ldb, work, ib )
         END DO
*
      ELSE IF( right .AND. tran ) THEN
*
         kf = ((k-1)/nb)*nb+1
         DO i = kf, 1, -nb
            ib = min( nb, k-i+1 )
            mb = min( n-l+i+ib-1, n )
            IF( i.GE.l ) THEN
               lb = 0
            ELSE
               lb = mb-n+l-i+1
            END IF
            CALL dtprfb( 'R', 'T', 'F', 'C', m, mb, ib, lb,
     $                   v( 1, i ), ldv, t( 1, i ), ldt,
     $                   a( 1, i ), lda, b, ldb, work, m )
         END DO
*
      END IF
*
      RETURN
*
*     End of DTPMQRT
*
      END