zla_herfsx_extended.f

*> \brief \b ZLA_HERFSX_EXTENDED improves the computed solution to a system of linear equations for Hermitian indefinite matrices by performing extra-precise iterative refinement and provides error bounds and backward error estimates for the solution.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download ZLA_HERFSX_EXTENDED + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zla_herfsx_extended.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zla_herfsx_extended.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zla_herfsx_extended.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZLA_HERFSX_EXTENDED( PREC_TYPE, UPLO, N, NRHS, A, LDA,
*                                       AF, LDAF, IPIV, COLEQU, C, B, LDB,
*                                       Y, LDY, BERR_OUT, N_NORMS,
*                                       ERR_BNDS_NORM, ERR_BNDS_COMP, RES,
*                                       AYB, DY, Y_TAIL, RCOND, ITHRESH,
*                                       RTHRESH, DZ_UB, IGNORE_CWISE,
*                                       INFO )
*
*       .. Scalar Arguments ..
*       INTEGER            INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
*      $                   N_NORMS, ITHRESH
*       CHARACTER          UPLO
*       LOGICAL            COLEQU, IGNORE_CWISE
*       DOUBLE PRECISION   RTHRESH, DZ_UB
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * )
*       COMPLEX*16         A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
*      $                   Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
*       DOUBLE PRECISION   C( * ), AYB( * ), RCOND, BERR_OUT( * ),
*      $                   ERR_BNDS_NORM( NRHS, * ),
*      $                   ERR_BNDS_COMP( NRHS, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZLA_HERFSX_EXTENDED improves the computed solution to a system of
*> linear equations by performing extra-precise iterative refinement
*> and provides error bounds and backward error estimates for the solution.
*> This subroutine is called by ZHERFSX to perform iterative refinement.
*> In addition to normwise error bound, the code provides maximum
*> componentwise error bound if possible. See comments for ERR_BNDS_NORM
*> and ERR_BNDS_COMP for details of the error bounds. Note that this
*> subroutine is only responsible for setting the second fields of
*> ERR_BNDS_NORM and ERR_BNDS_COMP.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] PREC_TYPE
*> \verbatim
*>          PREC_TYPE is INTEGER
*>     Specifies the intermediate precision to be used in refinement.
*>     The value is defined by ILAPREC(P) where P is a CHARACTER and P
*>          = 'S':  Single
*>          = 'D':  Double
*>          = 'I':  Indigenous
*>          = 'X' or 'E':  Extra
*> \endverbatim
*>
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>       = 'U':  Upper triangle of A is stored;
*>       = 'L':  Lower triangle of A is stored.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>     The number of linear equations, i.e., the order of the
*>     matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>     The number of right-hand-sides, i.e., the number of columns of the
*>     matrix B.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,N)
*>     On entry, the N-by-N matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>     The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in] AF
*> \verbatim
*>          AF is COMPLEX*16 array, dimension (LDAF,N)
*>     The block diagonal matrix D and the multipliers used to
*>     obtain the factor U or L as computed by ZHETRF.
*> \endverbatim
*>
*> \param[in] LDAF
*> \verbatim
*>          LDAF is INTEGER
*>     The leading dimension of the array AF.  LDAF >= max(1,N).
*> \endverbatim
*>
*> \param[in] IPIV
*> \verbatim
*>          IPIV is INTEGER array, dimension (N)
*>     Details of the interchanges and the block structure of D
*>     as determined by ZHETRF.
*> \endverbatim
*>
*> \param[in] COLEQU
*> \verbatim
*>          COLEQU is LOGICAL
*>     If .TRUE. then column equilibration was done to A before calling
*>     this routine. This is needed to compute the solution and error
*>     bounds correctly.
*> \endverbatim
*>
*> \param[in] C
*> \verbatim
*>          C is DOUBLE PRECISION array, dimension (N)
*>     The column scale factors for A. If COLEQU = .FALSE., C
*>     is not accessed. If C is input, each element of C should be a power
*>     of the radix to ensure a reliable solution and error estimates.
*>     Scaling by powers of the radix does not cause rounding errors unless
*>     the result underflows or overflows. Rounding errors during scaling
*>     lead to refining with a matrix that is not equivalent to the
*>     input matrix, producing error estimates that may not be
*>     reliable.
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*>          B is COMPLEX*16 array, dimension (LDB,NRHS)
*>     The right-hand-side matrix B.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>     The leading dimension of the array B.  LDB >= max(1,N).
*> \endverbatim
*>
*> \param[in,out] Y
*> \verbatim
*>          Y is COMPLEX*16 array, dimension (LDY,NRHS)
*>     On entry, the solution matrix X, as computed by ZHETRS.
*>     On exit, the improved solution matrix Y.
*> \endverbatim
*>
*> \param[in] LDY
*> \verbatim
*>          LDY is INTEGER
*>     The leading dimension of the array Y.  LDY >= max(1,N).
*> \endverbatim
*>
*> \param[out] BERR_OUT
*> \verbatim
*>          BERR_OUT is DOUBLE PRECISION array, dimension (NRHS)
*>     On exit, BERR_OUT(j) contains the componentwise relative backward
*>     error for right-hand-side j from the formula
*>         max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
*>     where abs(Z) is the componentwise absolute value of the matrix
*>     or vector Z. This is computed by ZLA_LIN_BERR.
*> \endverbatim
*>
*> \param[in] N_NORMS
*> \verbatim
*>          N_NORMS is INTEGER
*>     Determines which error bounds to return (see ERR_BNDS_NORM
*>     and ERR_BNDS_COMP).
*>     If N_NORMS >= 1 return normwise error bounds.
*>     If N_NORMS >= 2 return componentwise error bounds.
*> \endverbatim
*>
*> \param[in,out] ERR_BNDS_NORM
*> \verbatim
*>          ERR_BNDS_NORM is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
*>     For each right-hand side, this array contains information about
*>     various error bounds and condition numbers corresponding to the
*>     normwise relative error, which is defined as follows:
*>
*>     Normwise relative error in the ith solution vector:
*>             max_j (abs(XTRUE(j,i) - X(j,i)))
*>            ------------------------------
*>                  max_j abs(X(j,i))
*>
*>     The array is indexed by the type of error information as described
*>     below. There currently are up to three pieces of information
*>     returned.
*>
*>     The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
*>     right-hand side.
*>
*>     The second index in ERR_BNDS_NORM(:,err) contains the following
*>     three fields:
*>     err = 1 "Trust/don't trust" boolean. Trust the answer if the
*>              reciprocal condition number is less than the threshold
*>              sqrt(n) * slamch('Epsilon').
*>
*>     err = 2 "Guaranteed" error bound: The estimated forward error,
*>              almost certainly within a factor of 10 of the true error
*>              so long as the next entry is greater than the threshold
*>              sqrt(n) * slamch('Epsilon'). This error bound should only
*>              be trusted if the previous boolean is true.
*>
*>     err = 3  Reciprocal condition number: Estimated normwise
*>              reciprocal condition number.  Compared with the threshold
*>              sqrt(n) * slamch('Epsilon') to determine if the error
*>              estimate is "guaranteed". These reciprocal condition
*>              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
*>              appropriately scaled matrix Z.
*>              Let Z = S*A, where S scales each row by a power of the
*>              radix so all absolute row sums of Z are approximately 1.
*>
*>     This subroutine is only responsible for setting the second field
*>     above.
*>     See Lapack Working Note 165 for further details and extra
*>     cautions.
*> \endverbatim
*>
*> \param[in,out] ERR_BNDS_COMP
*> \verbatim
*>          ERR_BNDS_COMP is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
*>     For each right-hand side, this array contains information about
*>     various error bounds and condition numbers corresponding to the
*>     componentwise relative error, which is defined as follows:
*>
*>     Componentwise relative error in the ith solution vector:
*>                    abs(XTRUE(j,i) - X(j,i))
*>             max_j ----------------------
*>                         abs(X(j,i))
*>
*>     The array is indexed by the right-hand side i (on which the
*>     componentwise relative error depends), and the type of error
*>     information as described below. There currently are up to three
*>     pieces of information returned for each right-hand side. If
*>     componentwise accuracy is not requested (PARAMS(3) = 0.0), then
*>     ERR_BNDS_COMP is not accessed.  If N_ERR_BNDS < 3, then at most
*>     the first (:,N_ERR_BNDS) entries are returned.
*>
*>     The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
*>     right-hand side.
*>
*>     The second index in ERR_BNDS_COMP(:,err) contains the following
*>     three fields:
*>     err = 1 "Trust/don't trust" boolean. Trust the answer if the
*>              reciprocal condition number is less than the threshold
*>              sqrt(n) * slamch('Epsilon').
*>
*>     err = 2 "Guaranteed" error bound: The estimated forward error,
*>              almost certainly within a factor of 10 of the true error
*>              so long as the next entry is greater than the threshold
*>              sqrt(n) * slamch('Epsilon'). This error bound should only
*>              be trusted if the previous boolean is true.
*>
*>     err = 3  Reciprocal condition number: Estimated componentwise
*>              reciprocal condition number.  Compared with the threshold
*>              sqrt(n) * slamch('Epsilon') to determine if the error
*>              estimate is "guaranteed". These reciprocal condition
*>              numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
*>              appropriately scaled matrix Z.
*>              Let Z = S*(A*diag(x)), where x is the solution for the
*>              current right-hand side and S scales each row of
*>              A*diag(x) by a power of the radix so all absolute row
*>              sums of Z are approximately 1.
*>
*>     This subroutine is only responsible for setting the second field
*>     above.
*>     See Lapack Working Note 165 for further details and extra
*>     cautions.
*> \endverbatim
*>
*> \param[in] RES
*> \verbatim
*>          RES is COMPLEX*16 array, dimension (N)
*>     Workspace to hold the intermediate residual.
*> \endverbatim
*>
*> \param[in] AYB
*> \verbatim
*>          AYB is DOUBLE PRECISION array, dimension (N)
*>     Workspace.
*> \endverbatim
*>
*> \param[in] DY
*> \verbatim
*>          DY is COMPLEX*16 array, dimension (N)
*>     Workspace to hold the intermediate solution.
*> \endverbatim
*>
*> \param[in] Y_TAIL
*> \verbatim
*>          Y_TAIL is COMPLEX*16 array, dimension (N)
*>     Workspace to hold the trailing bits of the intermediate solution.
*> \endverbatim
*>
*> \param[in] RCOND
*> \verbatim
*>          RCOND is DOUBLE PRECISION
*>     Reciprocal scaled condition number.  This is an estimate of the
*>     reciprocal Skeel condition number of the matrix A after
*>     equilibration (if done).  If this is less than the machine
*>     precision (in particular, if it is zero), the matrix is singular
*>     to working precision.  Note that the error may still be small even
*>     if this number is very small and the matrix appears ill-
*>     conditioned.
*> \endverbatim
*>
*> \param[in] ITHRESH
*> \verbatim
*>          ITHRESH is INTEGER
*>     The maximum number of residual computations allowed for
*>     refinement. The default is 10. For 'aggressive' set to 100 to
*>     permit convergence using approximate factorizations or
*>     factorizations other than LU. If the factorization uses a
*>     technique other than Gaussian elimination, the guarantees in
*>     ERR_BNDS_NORM and ERR_BNDS_COMP may no longer be trustworthy.
*> \endverbatim
*>
*> \param[in] RTHRESH
*> \verbatim
*>          RTHRESH is DOUBLE PRECISION
*>     Determines when to stop refinement if the error estimate stops
*>     decreasing. Refinement will stop when the next solution no longer
*>     satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
*>     the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
*>     default value is 0.5. For 'aggressive' set to 0.9 to permit
*>     convergence on extremely ill-conditioned matrices. See LAWN 165
*>     for more details.
*> \endverbatim
*>
*> \param[in] DZ_UB
*> \verbatim
*>          DZ_UB is DOUBLE PRECISION
*>     Determines when to start considering componentwise convergence.
*>     Componentwise convergence is only considered after each component
*>     of the solution Y is stable, which we define as the relative
*>     change in each component being less than DZ_UB. The default value
*>     is 0.25, requiring the first bit to be stable. See LAWN 165 for
*>     more details.
*> \endverbatim
*>
*> \param[in] IGNORE_CWISE
*> \verbatim
*>          IGNORE_CWISE is LOGICAL
*>     If .TRUE. then ignore componentwise convergence. Default value
*>     is .FALSE..
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>       = 0:  Successful exit.
*>       < 0:  if INFO = -i, the ith argument to ZLA_HERFSX_EXTENDED had an illegal
*>             value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup la_herfsx_extended
*
*  =====================================================================
      SUBROUTINE zla_herfsx_extended( PREC_TYPE, UPLO, N, NRHS, A, LDA,
     $                                AF, LDAF, IPIV, COLEQU, C, B, LDB,
     $                                Y, LDY, BERR_OUT, N_NORMS,
     $                                ERR_BNDS_NORM, ERR_BNDS_COMP, RES,
     $                                AYB, DY, Y_TAIL, RCOND, ITHRESH,
     $                                RTHRESH, DZ_UB, IGNORE_CWISE,
     $                                INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
     $                   n_norms, ithresh
      CHARACTER          UPLO
      LOGICAL            COLEQU, IGNORE_CWISE
      DOUBLE PRECISION   RTHRESH, DZ_UB
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      COMPLEX*16         A( lda, * ), AF( ldaf, * ), B( ldb, * ),
     $                   y( ldy, * ), res( * ), dy( * ), y_tail( * )
      DOUBLE PRECISION   C( * ), AYB( * ), RCOND, BERR_OUT( * ),
     $                   err_bnds_norm( nrhs, * ),
     $                   err_bnds_comp( nrhs, * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            UPLO2, CNT, I, J, X_STATE, Z_STATE,
     $                   y_prec_state
      DOUBLE PRECISION   YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
     $                   dzrat, prevnormdx, prev_dz_z, dxratmax,
     $                   dzratmax, dx_x, dz_z, final_dx_x, final_dz_z,
     $                   eps, hugeval, incr_thresh
      LOGICAL            INCR_PREC, UPPER
      COMPLEX*16         ZDUM
*     ..
*     .. Parameters ..
      INTEGER            UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
     $                   noprog_state, base_residual, extra_residual,
     $                   extra_y
      parameter( unstable_state = 0, working_state = 1,
     $                   conv_state = 2, noprog_state = 3 )
      parameter( base_residual = 0, extra_residual = 1,
     $                   extra_y = 2 )
      INTEGER            FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
      INTEGER            RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
      INTEGER            CMP_ERR_I, PIV_GROWTH_I
      parameter( final_nrm_err_i = 1, final_cmp_err_i = 2,
     $                   berr_i = 3 )
      parameter( rcond_i = 4, nrm_rcond_i = 5, nrm_err_i = 6 )
      parameter( cmp_rcond_i = 7, cmp_err_i = 8,
     $                   piv_growth_i = 9 )
      INTEGER            LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
     $                   la_linrx_cwise_i
      parameter( la_linrx_itref_i = 1,
     $                   la_linrx_ithresh_i = 2 )
      parameter( la_linrx_cwise_i = 3 )
      INTEGER            LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
     $                   la_linrx_rcond_i
      parameter( la_linrx_trust_i = 1, la_linrx_err_i = 2 )
      parameter( la_linrx_rcond_i = 3 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           ilauplo
      INTEGER            ILAUPLO
*     ..
*     .. External Subroutines ..
      EXTERNAL           zaxpy, zcopy, zhetrs, zhemv, blas_zhemv_x,
     $                   blas_zhemv2_x, zla_heamv, zla_wwaddw,
     $                   zla_lin_berr
      DOUBLE PRECISION   DLAMCH
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dimag, max, min
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   CABS1
*     ..
*     .. Statement Function Definitions ..
      cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( nrhs.LT.0 ) THEN
         info = -4
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -6
      ELSE IF( ldaf.LT.max( 1, n ) ) THEN
         info = -8
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -13
      ELSE IF( ldy.LT.max( 1, n ) ) THEN
         info = -15
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZLA_HERFSX_EXTENDED', -info )
         RETURN
      END IF
      eps = dlamch( 'Epsilon' )
      hugeval = dlamch( 'Overflow' )
*     Force HUGEVAL to Inf
      hugeval = hugeval * hugeval
*     Using HUGEVAL may lead to spurious underflows.
      incr_thresh = dble( n ) * eps

      IF ( lsame( uplo, 'L' ) ) THEN
         uplo2 = ilauplo( 'L' )
      ELSE
         uplo2 = ilauplo( 'U' )
      ENDIF

      DO j = 1, nrhs
         y_prec_state = extra_residual
         IF ( y_prec_state .EQ. extra_y ) THEN
            DO i = 1, n
               y_tail( i ) = 0.0d+0
            END DO
         END IF

         dxrat = 0.0d+0
         dxratmax = 0.0d+0
         dzrat = 0.0d+0
         dzratmax = 0.0d+0
         final_dx_x = hugeval
         final_dz_z = hugeval
         prevnormdx = hugeval
         prev_dz_z = hugeval
         dz_z = hugeval
         dx_x = hugeval

         x_state = working_state
         z_state = unstable_state
         incr_prec = .false.

         DO cnt = 1, ithresh
*
*         Compute residual RES = B_s - op(A_s) * Y,
*             op(A) = A, A**T, or A**H depending on TRANS (and type).
*
            CALL zcopy( n, b( 1, j ), 1, res, 1 )
            IF ( y_prec_state .EQ. base_residual ) THEN
               CALL zhemv( uplo, n, dcmplx(-1.0d+0), a, lda, y( 1, j ),
     $              1, dcmplx(1.0d+0), res, 1 )
            ELSE IF ( y_prec_state .EQ. extra_residual ) THEN
               CALL blas_zhemv_x( uplo2, n, dcmplx(-1.0d+0), a, lda,
     $              y( 1, j ), 1, dcmplx(1.0d+0), res, 1, prec_type)
            ELSE
               CALL blas_zhemv2_x(uplo2, n, dcmplx(-1.0d+0), a, lda,
     $              y(1, j), y_tail, 1, dcmplx(1.0d+0), res, 1,
     $     prec_type)
            END IF

!         XXX: RES is no longer needed.
            CALL zcopy( n, res, 1, dy, 1 )
            CALL zhetrs( uplo, n, 1, af, ldaf, ipiv, dy, n, info )
*
*         Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
*
            normx = 0.0d+0
            normy = 0.0d+0
            normdx = 0.0d+0
            dz_z = 0.0d+0
            ymin = hugeval

            DO i = 1, n
               yk = cabs1( y( i, j ) )
               dyk = cabs1( dy( i ) )

               IF (yk .NE. 0.0d+0) THEN
                  dz_z = max( dz_z, dyk / yk )
               ELSE IF ( dyk .NE. 0.0d+0 ) THEN
                  dz_z = hugeval
               END IF

               ymin = min( ymin, yk )

               normy = max( normy, yk )

               IF ( colequ ) THEN
                  normx = max( normx, yk * c( i ) )
                  normdx = max( normdx, dyk * c( i ) )
               ELSE
                  normx = normy
                  normdx = max( normdx, dyk )
               END IF
            END DO

            IF ( normx .NE. 0.0d+0 ) THEN
               dx_x = normdx / normx
            ELSE IF ( normdx .EQ. 0.0d+0 ) THEN
               dx_x = 0.0d+0
            ELSE
               dx_x = hugeval
            END IF

            dxrat = normdx / prevnormdx
            dzrat = dz_z / prev_dz_z
*
*         Check termination criteria.
*
            IF ( ymin*rcond .LT. incr_thresh*normy
     $           .AND. y_prec_state .LT. extra_y )
     $           incr_prec = .true.

            IF ( x_state .EQ. noprog_state .AND. dxrat .LE. rthresh )
     $           x_state = working_state
            IF ( x_state .EQ. working_state ) THEN
               IF ( dx_x .LE. eps ) THEN
                  x_state = conv_state
               ELSE IF ( dxrat .GT. rthresh ) THEN
                  IF ( y_prec_state .NE. extra_y ) THEN
                     incr_prec = .true.
                  ELSE
                     x_state = noprog_state
                  END IF
               ELSE
                  IF (dxrat .GT. dxratmax) dxratmax = dxrat
               END IF
               IF ( x_state .GT. working_state ) final_dx_x = dx_x
            END IF

            IF ( z_state .EQ. unstable_state .AND. dz_z .LE. dz_ub )
     $           z_state = working_state
            IF ( z_state .EQ. noprog_state .AND. dzrat .LE. rthresh )
     $           z_state = working_state
            IF ( z_state .EQ. working_state ) THEN
               IF ( dz_z .LE. eps ) THEN
                  z_state = conv_state
               ELSE IF ( dz_z .GT. dz_ub ) THEN
                  z_state = unstable_state
                  dzratmax = 0.0d+0
                  final_dz_z = hugeval
               ELSE IF ( dzrat .GT. rthresh ) THEN
                  IF ( y_prec_state .NE. extra_y ) THEN
                     incr_prec = .true.
                  ELSE
                     z_state = noprog_state
                  END IF
               ELSE
                  IF ( dzrat .GT. dzratmax ) dzratmax = dzrat
               END IF
               IF ( z_state .GT. working_state ) final_dz_z = dz_z
            END IF

            IF ( x_state.NE.working_state.AND.
     $           ( ignore_cwise.OR.z_state.NE.working_state ) )
     $           GOTO 666

            IF ( incr_prec ) THEN
               incr_prec = .false.
               y_prec_state = y_prec_state + 1
               DO i = 1, n
                  y_tail( i ) = 0.0d+0
               END DO
            END IF

            prevnormdx = normdx
            prev_dz_z = dz_z
*
*           Update soluton.
*
            IF ( y_prec_state .LT. extra_y ) THEN
               CALL zaxpy( n, dcmplx(1.0d+0), dy, 1, y(1,j), 1 )
            ELSE
               CALL zla_wwaddw( n, y(1,j), y_tail, dy )
            END IF

         END DO
*        Target of "IF (Z_STOP .AND. X_STOP)".  Sun's f77 won't EXIT.
 666     CONTINUE
*
*     Set final_* when cnt hits ithresh.
*
         IF ( x_state .EQ. working_state ) final_dx_x = dx_x
         IF ( z_state .EQ. working_state ) final_dz_z = dz_z
*
*     Compute error bounds.
*
         IF ( n_norms .GE. 1 ) THEN
            err_bnds_norm( j, la_linrx_err_i ) =
     $           final_dx_x / (1 - dxratmax)
         END IF
         IF (n_norms .GE. 2) THEN
            err_bnds_comp( j, la_linrx_err_i ) =
     $           final_dz_z / (1 - dzratmax)
         END IF
*
*     Compute componentwise relative backward error from formula
*         max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
*     where abs(Z) is the componentwise absolute value of the matrix
*     or vector Z.
*
*         Compute residual RES = B_s - op(A_s) * Y,
*             op(A) = A, A**T, or A**H depending on TRANS (and type).
*
         CALL zcopy( n, b( 1, j ), 1, res, 1 )
         CALL zhemv( uplo, n, dcmplx(-1.0d+0), a, lda, y(1,j), 1,
     $        dcmplx(1.0d+0), res, 1 )

         DO i = 1, n
            ayb( i ) = cabs1( b( i, j ) )
         END DO
*
*     Compute abs(op(A_s))*abs(Y) + abs(B_s).
*
         CALL zla_heamv( uplo2, n, 1.0d+0,
     $        a, lda, y(1, j), 1, 1.0d+0, ayb, 1 )

         CALL zla_lin_berr( n, n, 1, res, ayb, berr_out( j ) )
*
*     End of loop for each RHS.
*
      END DO
*
      RETURN
*
*     End of ZLA_HERFSX_EXTENDED
*
      END