d5/df7/cla__porcond__c_8f_source.html

 *> \brief \b CLA_PORCOND_C computes the infinity norm condition number of op(A)*inv(diag(c)) for Hermitian positive-definite matrices.
 *
 *  =========== DOCUMENTATION ===========
 *
 * Online html documentation available at
 *            http://www.netlib.org/lapack/explore-html/
 *
 *> \htmlonly
 *> Download CLA_PORCOND_C + dependencies
 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cla_porcond_c.f">
 *> [TGZ]</a>
 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cla_porcond_c.f">
 *> [ZIP]</a>
 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cla_porcond_c.f">
 *> [TXT]</a>
 *> \endhtmlonly
 *
 *  Definition:
 *  ===========
 *
 *       REAL FUNCTION CLA_PORCOND_C( UPLO, N, A, LDA, AF, LDAF, C, CAPPLY,
 *                                    INFO, WORK, RWORK )
 *
 *       .. Scalar Arguments ..
 *       CHARACTER          UPLO
 *       LOGICAL            CAPPLY
 *       INTEGER            N, LDA, LDAF, INFO
 *       ..
 *       .. Array Arguments ..
 *       COMPLEX            A( LDA, * ), AF( LDAF, * ), WORK( * )
 *       REAL               C( * ), RWORK( * )
 *       ..
 *
 *
 *> \par Purpose:
 *  =============
 *>
 *> \verbatim
 *>
 *>    CLA_PORCOND_C Computes the infinity norm condition number of
 *>    op(A) * inv(diag(C)) where C is a REAL vector
 *> \endverbatim
 *
 *  Arguments:
 *  ==========
 *
 *> \param[in] UPLO
 *> \verbatim
 *>          UPLO is CHARACTER*1
 *>       = 'U':  Upper triangle of A is stored;
 *>       = 'L':  Lower triangle of A is stored.
 *> \endverbatim
 *>
 *> \param[in] N
 *> \verbatim
 *>          N is INTEGER
 *>     The number of linear equations, i.e., the order of the
 *>     matrix A.  N >= 0.
 *> \endverbatim
 *>
 *> \param[in] A
 *> \verbatim
 *>          A is COMPLEX array, dimension (LDA,N)
 *>     On entry, the N-by-N matrix A
 *> \endverbatim
 *>
 *> \param[in] LDA
 *> \verbatim
 *>          LDA is INTEGER
 *>     The leading dimension of the array A.  LDA >= max(1,N).
 *> \endverbatim
 *>
 *> \param[in] AF
 *> \verbatim
 *>          AF is COMPLEX array, dimension (LDAF,N)
 *>     The triangular factor U or L from the Cholesky factorization
 *>     A = U**H*U or A = L*L**H, as computed by CPOTRF.
 *> \endverbatim
 *>
 *> \param[in] LDAF
 *> \verbatim
 *>          LDAF is INTEGER
 *>     The leading dimension of the array AF.  LDAF >= max(1,N).
 *> \endverbatim
 *>
 *> \param[in] C
 *> \verbatim
 *>          C is REAL array, dimension (N)
 *>     The vector C in the formula op(A) * inv(diag(C)).
 *> \endverbatim
 *>
 *> \param[in] CAPPLY
 *> \verbatim
 *>          CAPPLY is LOGICAL
 *>     If .TRUE. then access the vector C in the formula above.
 *> \endverbatim
 *>
 *> \param[out] INFO
 *> \verbatim
 *>          INFO is INTEGER
 *>       = 0:  Successful exit.
 *>     i > 0:  The ith argument is invalid.
 *> \endverbatim
 *>
 *> \param[out] WORK
 *> \verbatim
 *>          WORK is COMPLEX array, dimension (2*N).
 *>     Workspace.
 *> \endverbatim
 *>
 *> \param[out] RWORK
 *> \verbatim
 *>          RWORK is REAL array, dimension (N).
 *>     Workspace.
 *> \endverbatim
 *
 *  Authors:
 *  ========
 *
 *> \author Univ. of Tennessee
 *> \author Univ. of California Berkeley
 *> \author Univ. of Colorado Denver
 *> \author NAG Ltd.
 *
 *> \ingroup la_porcond
 *
 *  =====================================================================
       REAL FUNCTION cla_porcond_c( UPLO, N, A, LDA, AF, LDAF, C, CAPPLY,
      $                             INFO, WORK, RWORK )
 *
 *  -- LAPACK computational routine --
 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 *
 *     .. Scalar Arguments ..
       CHARACTER          UPLO
       LOGICAL            CAPPLY
       INTEGER            N, LDA, LDAF, INFO
 *     ..
 *     .. Array Arguments ..
       COMPLEX            A( lda, * ), AF( ldaf, * ), WORK( * )
       REAL               C( * ), RWORK( * )
 *     ..
 *
 *  =====================================================================
 *
 *     .. Local Scalars ..
       INTEGER            KASE
       REAL               AINVNM, ANORM, TMP
       INTEGER            I, J
       LOGICAL            UP, UPPER
       COMPLEX            ZDUM
 *     ..
 *     .. Local Arrays ..
       INTEGER            ISAVE( 3 )
 *     ..
 *     .. External Functions ..
       LOGICAL            LSAME
       EXTERNAL           lsame
 *     ..
 *     .. External Subroutines ..
       EXTERNAL           clacn2, cpotrs, xerbla
 *     ..
 *     .. Intrinsic Functions ..
       INTRINSIC          abs, max, REAL, AIMAG
 *     ..
 *     .. Statement Functions ..
       REAL CABS1
 *     ..
 *     .. Statement Function Definitions ..
       cabs1( zdum ) = abs( REAL( ZDUM ) ) + abs( AIMAG( zdum ) )
 *     ..
 *     .. Executable Statements ..
 *
       cla_porcond_c = 0.0e+0
 *
       info = 0
       upper = lsame( uplo, 'U' )
       IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
          info = -1
       ELSE IF( n.LT.0 ) THEN
          info = -2
       ELSE IF( lda.LT.max( 1, n ) ) THEN
          info = -4
       ELSE IF( ldaf.LT.max( 1, n ) ) THEN
          info = -6
       END IF
       IF( info.NE.0 ) THEN
          CALL xerbla( 'CLA_PORCOND_C', -info )
          RETURN
       END IF
       up = .false.
       IF ( lsame( uplo, 'U' ) ) up = .true.
 *
 *     Compute norm of op(A)*op2(C).
 *
       anorm = 0.0e+0
       IF ( up ) THEN
          DO i = 1, n
             tmp = 0.0e+0
             IF ( capply ) THEN
                DO j = 1, i
                   tmp = tmp + cabs1( a( j, i ) ) / c( j )
                END DO
                DO j = i+1, n
                   tmp = tmp + cabs1( a( i, j ) ) / c( j )
                END DO
             ELSE
                DO j = 1, i
                   tmp = tmp + cabs1( a( j, i ) )
                END DO
                DO j = i+1, n
                   tmp = tmp + cabs1( a( i, j ) )
                END DO
             END IF
             rwork( i ) = tmp
             anorm = max( anorm, tmp )
          END DO
       ELSE
          DO i = 1, n
             tmp = 0.0e+0
             IF ( capply ) THEN
                DO j = 1, i
                   tmp = tmp + cabs1( a( i, j ) ) / c( j )
                END DO
                DO j = i+1, n
                   tmp = tmp + cabs1( a( j, i ) ) / c( j )
                END DO
             ELSE
                DO j = 1, i
                   tmp = tmp + cabs1( a( i, j ) )
                END DO
                DO j = i+1, n
                   tmp = tmp + cabs1( a( j, i ) )
                END DO
             END IF
             rwork( i ) = tmp
             anorm = max( anorm, tmp )
          END DO
       END IF
 *
 *     Quick return if possible.
 *
       IF( n.EQ.0 ) THEN
          cla_porcond_c = 1.0e+0
          RETURN
       ELSE IF( anorm .EQ. 0.0e+0 ) THEN
          RETURN
       END IF
 *
 *     Estimate the norm of inv(op(A)).
 *
       ainvnm = 0.0e+0
 *
       kase = 0
    10 CONTINUE
       CALL clacn2( n, work( n+1 ), work, ainvnm, kase, isave )
       IF( kase.NE.0 ) THEN
          IF( kase.EQ.2 ) THEN
 *
 *           Multiply by R.
 *
             DO i = 1, n
                work( i ) = work( i ) * rwork( i )
             END DO
 *
             IF ( up ) THEN
                CALL cpotrs( 'U', n, 1, af, ldaf,
      $            work, n, info )
             ELSE
                CALL cpotrs( 'L', n, 1, af, ldaf,
      $            work, n, info )
             ENDIF
 *
 *           Multiply by inv(C).
 *
             IF ( capply ) THEN
                DO i = 1, n
                   work( i ) = work( i ) * c( i )
                END DO
             END IF
          ELSE
 *
 *           Multiply by inv(C**H).
 *
             IF ( capply ) THEN
                DO i = 1, n
                   work( i ) = work( i ) * c( i )
                END DO
             END IF
 *
             IF ( up ) THEN
                CALL cpotrs( 'U', n, 1, af, ldaf,
      $            work, n, info )
             ELSE
                CALL cpotrs( 'L', n, 1, af, ldaf,
      $            work, n, info )
             END IF
 *
 *           Multiply by R.
 *
             DO i = 1, n
                work( i ) = work( i ) * rwork( i )
             END DO
          END IF
          GO TO 10
       END IF
 *
 *     Compute the estimate of the reciprocal condition number.
 *
       IF( ainvnm .NE. 0.0e+0 )
      $   cla_porcond_c = 1.0e+0 / ainvnm
 *
       RETURN
 *
 *     End of CLA_PORCOND_C
 *
       END
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60

clacn2
subroutine clacn2(N, V, X, EST, KASE, ISAVE)
CLACN2 estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vec...
Definition: clacn2.f:133

cla_porcond_c
real function cla_porcond_c(UPLO, N, A, LDA, AF, LDAF, C, CAPPLY, INFO, WORK, RWORK)
CLA_PORCOND_C computes the infinity norm condition number of op(A)*inv(diag(c)) for Hermitian positiv...
Definition: cla_porcond_c.f:130

cpotrs
subroutine cpotrs(UPLO, N, NRHS, A, LDA, B, LDB, INFO)
CPOTRS
Definition: cpotrs.f:110