zhetri_rook.f

*> \brief \b ZHETRI_ROOK computes the inverse of HE matrix using the factorization obtained with the bounded Bunch-Kaufman ("rook") diagonal pivoting method.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download ZHETRI_ROOK + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zhetri_rook.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zhetri_rook.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zhetri_rook.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZHETRI_ROOK( UPLO, N, A, LDA, IPIV, WORK, INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            INFO, LDA, N
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * )
*       COMPLEX*16         A( LDA, * ), WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZHETRI_ROOK computes the inverse of a complex Hermitian indefinite matrix
*> A using the factorization A = U*D*U**H or A = L*D*L**H computed by
*> ZHETRF_ROOK.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the details of the factorization are stored
*>          as an upper or lower triangular matrix.
*>          = 'U':  Upper triangular, form is A = U*D*U**H;
*>          = 'L':  Lower triangular, form is A = L*D*L**H.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,N)
*>          On entry, the block diagonal matrix D and the multipliers
*>          used to obtain the factor U or L as computed by ZHETRF_ROOK.
*>
*>          On exit, if INFO = 0, the (Hermitian) inverse of the original
*>          matrix.  If UPLO = 'U', the upper triangular part of the
*>          inverse is formed and the part of A below the diagonal is not
*>          referenced; if UPLO = 'L' the lower triangular part of the
*>          inverse is formed and the part of A above the diagonal is
*>          not referenced.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in] IPIV
*> \verbatim
*>          IPIV is INTEGER array, dimension (N)
*>          Details of the interchanges and the block structure of D
*>          as determined by ZHETRF_ROOK.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension (N)
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0: successful exit
*>          < 0: if INFO = -i, the i-th argument had an illegal value
*>          > 0: if INFO = i, D(i,i) = 0; the matrix is singular and its
*>               inverse could not be computed.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup hetri_rook
*
*> \par Contributors:
*  ==================
*>
*> \verbatim
*>
*>  November 2013,  Igor Kozachenko,
*>                  Computer Science Division,
*>                  University of California, Berkeley
*>
*>  September 2007, Sven Hammarling, Nicholas J. Higham, Craig Lucas,
*>                  School of Mathematics,
*>                  University of Manchester
*> \endverbatim
*
*  =====================================================================
      SUBROUTINE zhetri_rook( UPLO, N, A, LDA, IPIV, WORK, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, N
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      COMPLEX*16         A( lda, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE
      COMPLEX*16         CONE, CZERO
      parameter( one = 1.0d+0, cone = ( 1.0d+0, 0.0d+0 ),
     $                   czero = ( 0.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            J, K, KP, KSTEP
      DOUBLE PRECISION   AK, AKP1, D, T
      COMPLEX*16         AKKP1, TEMP
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      COMPLEX*16         ZDOTC
      EXTERNAL           lsame, zdotc
*     ..
*     .. External Subroutines ..
      EXTERNAL           zcopy, zhemv, zswap, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dconjg, max, dble
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZHETRI_ROOK', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Check that the diagonal matrix D is nonsingular.
*
      IF( upper ) THEN
*
*        Upper triangular storage: examine D from bottom to top
*
         DO 10 info = n, 1, -1
            IF( ipiv( info ).GT.0 .AND. a( info, info ).EQ.czero )
     $         RETURN
   10    CONTINUE
      ELSE
*
*        Lower triangular storage: examine D from top to bottom.
*
         DO 20 info = 1, n
            IF( ipiv( info ).GT.0 .AND. a( info, info ).EQ.czero )
     $         RETURN
   20    CONTINUE
      END IF
      info = 0
*
      IF( upper ) THEN
*
*        Compute inv(A) from the factorization A = U*D*U**H.
*
*        K is the main loop index, increasing from 1 to N in steps of
*        1 or 2, depending on the size of the diagonal blocks.
*
         k = 1
   30    CONTINUE
*
*        If K > N, exit from loop.
*
         IF( k.GT.n )
     $      GO TO 70
*
         IF( ipiv( k ).GT.0 ) THEN
*
*           1 x 1 diagonal block
*
*           Invert the diagonal block.
*
            a( k, k ) = one / dble( a( k, k ) )
*
*           Compute column K of the inverse.
*
            IF( k.GT.1 ) THEN
               CALL zcopy( k-1, a( 1, k ), 1, work, 1 )
               CALL zhemv( uplo, k-1, -cone, a, lda, work, 1, czero,
     $                     a( 1, k ), 1 )
               a( k, k ) = a( k, k ) - dble( zdotc( k-1, work, 1, a( 1,
     $                     k ), 1 ) )
            END IF
            kstep = 1
         ELSE
*
*           2 x 2 diagonal block
*
*           Invert the diagonal block.
*
            t = abs( a( k, k+1 ) )
            ak = dble( a( k, k ) ) / t
            akp1 = dble( a( k+1, k+1 ) ) / t
            akkp1 = a( k, k+1 ) / t
            d = t*( ak*akp1-one )
            a( k, k ) = akp1 / d
            a( k+1, k+1 ) = ak / d
            a( k, k+1 ) = -akkp1 / d
*
*           Compute columns K and K+1 of the inverse.
*
            IF( k.GT.1 ) THEN
               CALL zcopy( k-1, a( 1, k ), 1, work, 1 )
               CALL zhemv( uplo, k-1, -cone, a, lda, work, 1, czero,
     $                     a( 1, k ), 1 )
               a( k, k ) = a( k, k ) - dble( zdotc( k-1, work, 1, a( 1,
     $                     k ), 1 ) )
               a( k, k+1 ) = a( k, k+1 ) -
     $                       zdotc( k-1, a( 1, k ), 1, a( 1, k+1 ), 1 )
               CALL zcopy( k-1, a( 1, k+1 ), 1, work, 1 )
               CALL zhemv( uplo, k-1, -cone, a, lda, work, 1, czero,
     $                     a( 1, k+1 ), 1 )
               a( k+1, k+1 ) = a( k+1, k+1 ) -
     $                         dble( zdotc( k-1, work, 1, a( 1, k+1 ),
     $                         1 ) )
            END IF
            kstep = 2
         END IF
*
         IF( kstep.EQ.1 ) THEN
*
*           Interchange rows and columns K and IPIV(K) in the leading
*           submatrix A(1:k,1:k)
*
            kp = ipiv( k )
            IF( kp.NE.k ) THEN
*
               IF( kp.GT.1 )
     $            CALL zswap( kp-1, a( 1, k ), 1, a( 1, kp ), 1 )
*
               DO 40 j = kp + 1, k - 1
                  temp = dconjg( a( j, k ) )
                  a( j, k ) = dconjg( a( kp, j ) )
                  a( kp, j ) = temp
   40          CONTINUE
*
               a( kp, k ) = dconjg( a( kp, k ) )
*
               temp = a( k, k )
               a( k, k ) = a( kp, kp )
               a( kp, kp ) = temp
            END IF
         ELSE
*
*           Interchange rows and columns K and K+1 with -IPIV(K) and
*           -IPIV(K+1) in the leading submatrix A(k+1:n,k+1:n)
*
*           (1) Interchange rows and columns K and -IPIV(K)
*
            kp = -ipiv( k )
            IF( kp.NE.k ) THEN
*
               IF( kp.GT.1 )
     $            CALL zswap( kp-1, a( 1, k ), 1, a( 1, kp ), 1 )
*
               DO 50 j = kp + 1, k - 1
                  temp = dconjg( a( j, k ) )
                  a( j, k ) = dconjg( a( kp, j ) )
                  a( kp, j ) = temp
   50          CONTINUE
*
               a( kp, k ) = dconjg( a( kp, k ) )
*
               temp = a( k, k )
               a( k, k ) = a( kp, kp )
               a( kp, kp ) = temp
*
               temp = a( k, k+1 )
               a( k, k+1 ) = a( kp, k+1 )
               a( kp, k+1 ) = temp
            END IF
*
*           (2) Interchange rows and columns K+1 and -IPIV(K+1)
*
            k = k + 1
            kp = -ipiv( k )
            IF( kp.NE.k ) THEN
*
               IF( kp.GT.1 )
     $            CALL zswap( kp-1, a( 1, k ), 1, a( 1, kp ), 1 )
*
               DO 60 j = kp + 1, k - 1
                  temp = dconjg( a( j, k ) )
                  a( j, k ) = dconjg( a( kp, j ) )
                  a( kp, j ) = temp
   60          CONTINUE
*
               a( kp, k ) = dconjg( a( kp, k ) )
*
               temp = a( k, k )
               a( k, k ) = a( kp, kp )
               a( kp, kp ) = temp
            END IF
         END IF
*
         k = k + 1
         GO TO 30
   70    CONTINUE
*
      ELSE
*
*        Compute inv(A) from the factorization A = L*D*L**H.
*
*        K is the main loop index, decreasing from N to 1 in steps of
*        1 or 2, depending on the size of the diagonal blocks.
*
         k = n
   80    CONTINUE
*
*        If K < 1, exit from loop.
*
         IF( k.LT.1 )
     $      GO TO 120
*
         IF( ipiv( k ).GT.0 ) THEN
*
*           1 x 1 diagonal block
*
*           Invert the diagonal block.
*
            a( k, k ) = one / dble( a( k, k ) )
*
*           Compute column K of the inverse.
*
            IF( k.LT.n ) THEN
               CALL zcopy( n-k, a( k+1, k ), 1, work, 1 )
               CALL zhemv( uplo, n-k, -cone, a( k+1, k+1 ), lda, work,
     $                     1, czero, a( k+1, k ), 1 )
               a( k, k ) = a( k, k ) - dble( zdotc( n-k, work, 1,
     $                     a( k+1, k ), 1 ) )
            END IF
            kstep = 1
         ELSE
*
*           2 x 2 diagonal block
*
*           Invert the diagonal block.
*
            t = abs( a( k, k-1 ) )
            ak = dble( a( k-1, k-1 ) ) / t
            akp1 = dble( a( k, k ) ) / t
            akkp1 = a( k, k-1 ) / t
            d = t*( ak*akp1-one )
            a( k-1, k-1 ) = akp1 / d
            a( k, k ) = ak / d
            a( k, k-1 ) = -akkp1 / d
*
*           Compute columns K-1 and K of the inverse.
*
            IF( k.LT.n ) THEN
               CALL zcopy( n-k, a( k+1, k ), 1, work, 1 )
               CALL zhemv( uplo, n-k, -cone, a( k+1, k+1 ), lda, work,
     $                     1, czero, a( k+1, k ), 1 )
               a( k, k ) = a( k, k ) - dble( zdotc( n-k, work, 1,
     $                     a( k+1, k ), 1 ) )
               a( k, k-1 ) = a( k, k-1 ) -
     $                       zdotc( n-k, a( k+1, k ), 1, a( k+1, k-1 ),
     $                       1 )
               CALL zcopy( n-k, a( k+1, k-1 ), 1, work, 1 )
               CALL zhemv( uplo, n-k, -cone, a( k+1, k+1 ), lda, work,
     $                     1, czero, a( k+1, k-1 ), 1 )
               a( k-1, k-1 ) = a( k-1, k-1 ) -
     $                         dble( zdotc( n-k, work, 1, a( k+1, k-1 ),
     $                         1 ) )
            END IF
            kstep = 2
         END IF
*
         IF( kstep.EQ.1 ) THEN
*
*           Interchange rows and columns K and IPIV(K) in the trailing
*           submatrix A(k:n,k:n)
*
            kp = ipiv( k )
            IF( kp.NE.k ) THEN
*
               IF( kp.LT.n )
     $            CALL zswap( n-kp, a( kp+1, k ), 1, a( kp+1, kp ), 1 )
*
               DO 90 j = k + 1, kp - 1
                  temp = dconjg( a( j, k ) )
                  a( j, k ) = dconjg( a( kp, j ) )
                  a( kp, j ) = temp
   90          CONTINUE
*
               a( kp, k ) = dconjg( a( kp, k ) )
*
               temp = a( k, k )
               a( k, k ) = a( kp, kp )
               a( kp, kp ) = temp
            END IF
         ELSE
*
*           Interchange rows and columns K and K-1 with -IPIV(K) and
*           -IPIV(K-1) in the trailing submatrix A(k-1:n,k-1:n)
*
*           (1) Interchange rows and columns K and -IPIV(K)
*
            kp = -ipiv( k )
            IF( kp.NE.k ) THEN
*
               IF( kp.LT.n )
     $            CALL zswap( n-kp, a( kp+1, k ), 1, a( kp+1, kp ), 1 )
*
               DO 100 j = k + 1, kp - 1
                  temp = dconjg( a( j, k ) )
                  a( j, k ) = dconjg( a( kp, j ) )
                  a( kp, j ) = temp
  100         CONTINUE
*
               a( kp, k ) = dconjg( a( kp, k ) )
*
               temp = a( k, k )
               a( k, k ) = a( kp, kp )
               a( kp, kp ) = temp
*
               temp = a( k, k-1 )
               a( k, k-1 ) = a( kp, k-1 )
               a( kp, k-1 ) = temp
            END IF
*
*           (2) Interchange rows and columns K-1 and -IPIV(K-1)
*
            k = k - 1
            kp = -ipiv( k )
            IF( kp.NE.k ) THEN
*
               IF( kp.LT.n )
     $            CALL zswap( n-kp, a( kp+1, k ), 1, a( kp+1, kp ), 1 )
*
               DO 110 j = k + 1, kp - 1
                  temp = dconjg( a( j, k ) )
                  a( j, k ) = dconjg( a( kp, j ) )
                  a( kp, j ) = temp
  110         CONTINUE
*
               a( kp, k ) = dconjg( a( kp, k ) )
*
               temp = a( k, k )
               a( k, k ) = a( kp, kp )
               a( kp, kp ) = temp
            END IF
         END IF
*
         k = k - 1
         GO TO 80
  120    CONTINUE
      END IF
*
      RETURN
*
*     End of ZHETRI_ROOK
*
      END