d1/d25/dlansy_8f_source.html

 *> \brief \b DLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a real symmetric matrix.
 *
 *  =========== DOCUMENTATION ===========
 *
 * Online html documentation available at
 *            http://www.netlib.org/lapack/explore-html/
 *
 *> \htmlonly
 *> Download DLANSY + dependencies
 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlansy.f">
 *> [TGZ]</a>
 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlansy.f">
 *> [ZIP]</a>
 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlansy.f">
 *> [TXT]</a>
 *> \endhtmlonly
 *
 *  Definition:
 *  ===========
 *
 *       DOUBLE PRECISION FUNCTION DLANSY( NORM, UPLO, N, A, LDA, WORK )
 *
 *       .. Scalar Arguments ..
 *       CHARACTER          NORM, UPLO
 *       INTEGER            LDA, N
 *       ..
 *       .. Array Arguments ..
 *       DOUBLE PRECISION   A( LDA, * ), WORK( * )
 *       ..
 *
 *
 *> \par Purpose:
 *  =============
 *>
 *> \verbatim
 *>
 *> DLANSY  returns the value of the one norm,  or the Frobenius norm, or
 *> the  infinity norm,  or the  element of  largest absolute value  of a
 *> real symmetric matrix A.
 *> \endverbatim
 *>
 *> \return DLANSY
 *> \verbatim
 *>
 *>    DLANSY = ( max(abs(A(i,j))), NORM = 'M' or 'm'
 *>             (
 *>             ( norm1(A),         NORM = '1', 'O' or 'o'
 *>             (
 *>             ( normI(A),         NORM = 'I' or 'i'
 *>             (
 *>             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
 *>
 *> where  norm1  denotes the  one norm of a matrix (maximum column sum),
 *> normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 *> normF  denotes the  Frobenius norm of a matrix (square root of sum of
 *> squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
 *> \endverbatim
 *
 *  Arguments:
 *  ==========
 *
 *> \param[in] NORM
 *> \verbatim
 *>          NORM is CHARACTER*1
 *>          Specifies the value to be returned in DLANSY as described
 *>          above.
 *> \endverbatim
 *>
 *> \param[in] UPLO
 *> \verbatim
 *>          UPLO is CHARACTER*1
 *>          Specifies whether the upper or lower triangular part of the
 *>          symmetric matrix A is to be referenced.
 *>          = 'U':  Upper triangular part of A is referenced
 *>          = 'L':  Lower triangular part of A is referenced
 *> \endverbatim
 *>
 *> \param[in] N
 *> \verbatim
 *>          N is INTEGER
 *>          The order of the matrix A.  N >= 0.  When N = 0, DLANSY is
 *>          set to zero.
 *> \endverbatim
 *>
 *> \param[in] A
 *> \verbatim
 *>          A is DOUBLE PRECISION array, dimension (LDA,N)
 *>          The symmetric matrix A.  If UPLO = 'U', the leading n by n
 *>          upper triangular part of A contains the upper triangular part
 *>          of the matrix A, and the strictly lower triangular part of A
 *>          is not referenced.  If UPLO = 'L', the leading n by n lower
 *>          triangular part of A contains the lower triangular part of
 *>          the matrix A, and the strictly upper triangular part of A is
 *>          not referenced.
 *> \endverbatim
 *>
 *> \param[in] LDA
 *> \verbatim
 *>          LDA is INTEGER
 *>          The leading dimension of the array A.  LDA >= max(N,1).
 *> \endverbatim
 *>
 *> \param[out] WORK
 *> \verbatim
 *>          WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
 *>          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
 *>          WORK is not referenced.
 *> \endverbatim
 *
 *  Authors:
 *  ========
 *
 *> \author Univ. of Tennessee
 *> \author Univ. of California Berkeley
 *> \author Univ. of Colorado Denver
 *> \author NAG Ltd.
 *
 *> \ingroup lanhe
 *
 *  =====================================================================
       DOUBLE PRECISION FUNCTION dlansy( NORM, UPLO, N, A, LDA, WORK )
 *
 *  -- LAPACK auxiliary routine --
 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 *
 *     .. Scalar Arguments ..
       CHARACTER          NORM, UPLO
       INTEGER            LDA, N
 *     ..
 *     .. Array Arguments ..
       DOUBLE PRECISION   A( lda, * ), WORK( * )
 *     ..
 *
 * =====================================================================
 *
 *     .. Parameters ..
       DOUBLE PRECISION   ONE, ZERO
       parameter( one = 1.0d+0, zero = 0.0d+0 )
 *     ..
 *     .. Local Scalars ..
       INTEGER            I, J
       DOUBLE PRECISION   ABSA, SCALE, SUM, VALUE
 *     ..
 *     .. External Subroutines ..
       EXTERNAL           dlassq
 *     ..
 *     .. External Functions ..
       LOGICAL            LSAME, DISNAN
       EXTERNAL           lsame, disnan
 *     ..
 *     .. Intrinsic Functions ..
       INTRINSIC          abs, sqrt
 *     ..
 *     .. Executable Statements ..
 *
       IF( n.EQ.0 ) THEN
          VALUE = zero
       ELSE IF( lsame( norm, 'M' ) ) THEN
 *
 *        Find max(abs(A(i,j))).
 *
          VALUE = zero
          IF( lsame( uplo, 'U' ) ) THEN
             DO 20 j = 1, n
                DO 10 i = 1, j
                   sum = abs( a( i, j ) )
                   IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
    10          CONTINUE
    20       CONTINUE
          ELSE
             DO 40 j = 1, n
                DO 30 i = j, n
                   sum = abs( a( i, j ) )
                   IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
    30          CONTINUE
    40       CONTINUE
          END IF
       ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
      $         ( norm.EQ.'1' ) ) THEN
 *
 *        Find normI(A) ( = norm1(A), since A is symmetric).
 *
          VALUE = zero
          IF( lsame( uplo, 'U' ) ) THEN
             DO 60 j = 1, n
                sum = zero
                DO 50 i = 1, j - 1
                   absa = abs( a( i, j ) )
                   sum = sum + absa
                   work( i ) = work( i ) + absa
    50          CONTINUE
                work( j ) = sum + abs( a( j, j ) )
    60       CONTINUE
             DO 70 i = 1, n
                sum = work( i )
                IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
    70       CONTINUE
          ELSE
             DO 80 i = 1, n
                work( i ) = zero
    80       CONTINUE
             DO 100 j = 1, n
                sum = work( j ) + abs( a( j, j ) )
                DO 90 i = j + 1, n
                   absa = abs( a( i, j ) )
                   sum = sum + absa
                   work( i ) = work( i ) + absa
    90          CONTINUE
                IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
   100       CONTINUE
          END IF
       ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
 *
 *        Find normF(A).
 *
          scale = zero
          sum = one
          IF( lsame( uplo, 'U' ) ) THEN
             DO 110 j = 2, n
                CALL dlassq( j-1, a( 1, j ), 1, scale, sum )
   110       CONTINUE
          ELSE
             DO 120 j = 1, n - 1
                CALL dlassq( n-j, a( j+1, j ), 1, scale, sum )
   120       CONTINUE
          END IF
          sum = 2*sum
          CALL dlassq( n, a, lda+1, scale, sum )
          VALUE = scale*sqrt( sum )
       END IF
 *
       dlansy = VALUE
       RETURN
 *
 *     End of DLANSY
 *
       END
dlansy
double precision function dlansy(NORM, UPLO, N, A, LDA, WORK)
DLANSY returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a real symmetric matrix.
Definition: dlansy.f:122