001:       SUBROUTINE CORE_CUNMQR( SIDE, TRANS, M, N, IB, K,  A, LDA,
002:      $                       T, LDT, C, LDC, WORK, LDWORK, INFO )
003: 
004: *********************************************************************
005: *     PLASMA core_blas routine (version 2.1.0)                      *
006: *     Author: Hatem Ltaief                                          *
007: *     Release Date: November, 15th 2009                             *
008: *     PLASMA is a software package provided by Univ. of Tennessee,  *
009: *     Univ. of California Berkeley and Univ. of Colorado Denver.    *
010: *********************************************************************
011: *
012: *     .. Scalar Arguments ..
013:       CHARACTER          SIDE, TRANS
014:       INTEGER            M, N, K, IB, INFO
015:       INTEGER            LDA, LDT, LDC, LDWORK
016: *     ..
017: *     .. Array Arguments ..
018:       COMPLEX            A( LDA, * ), C( LDC, * )
019:       COMPLEX            T( LDT, * ), WORK( * )
020: *     ..
021: *
022: *  Purpose
023: *  =======
024: *
025: *  CORE_CUNMQR overwrites the general complex M-by-N tile C with
026: *
027: *                  SIDE = 'L'     SIDE = 'R'
028: *  TRANS = 'N':      Q * C          C * Q
029: *  TRANS = 'C':      Q**H * C       C * Q**H
030: *
031: *  where Q is a complex unitary matrix defined as the product of k
032: *  elementary reflectors
033: *
034: *        Q = H(1) H(2) . . . H(k)
035: *
036: *  as returned by CORE_CGEQRT. Q is of order M if SIDE = 'L' and of order N
037: *  if SIDE = 'R'.
038: *
039: *  Arguments
040: *  =========
041: *
042: *  SIDE    (input) CHARACTER*1
043: *          = 'L': apply Q or Q**H from the Left;
044: *          = 'R': apply Q or Q**H from the Right.
045: *
046: *  TRANS   (input) CHARACTER*1
047: *          = 'N':  No transpose, apply Q;
048: *          = 'T':  Transpose, apply Q**H.
049: *
050: *  M       (input) INTEGER
051: *          The number of rows of the tile C. M >= 0.
052: *
053: *  N       (input) INTEGER
054: *          The number of columns of the tile C. N >= 0.
055: *
056: *  K       (input) INTEGER
057: *          The number of elementary reflectors whose product defines
058: *          the matrix Q.
059: *          If SIDE = 'L', M >= K >= 0;
060: *          if SIDE = 'R', N >= K >= 0.
061: *
062: *  A       (input) COMPLEX array, dimension (LDA,K)
063: *          The i-th column must contain the vector which defines the
064: *          elementary reflector H(i), for i = 1,2,...,k, as returned by
065: *          CORE_CGEQRT in the first k columns of its array argument A.
066: *
067: *  LDA     (input) INTEGER
068: *          The leading dimension of the array A.
069: *          If SIDE = 'L', LDA >= max(1,M);
070: *          if SIDE = 'R', LDA >= max(1,N).
071: *
072: *  C       (input/output) COMPLEX array, dimension (LDC,N)
073: *          On entry, the M-by-N tile C.
074: *          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
075: *
076: *  LDC     (input) INTEGER
077: *          The leading dimension of the array C. LDC >= max(1,M).
078: *
079: *  WORK    (workspace/output) COMPLEX array, dimension (MAX(1,LDWORK))
080: *          On exit, if INFO = 0, WORK(1) returns the optimal LDWORK.
081: *
082: *  LDWORK   (input) INTEGER
083: *          The dimension of the array WORK.
084: *          If SIDE = 'L', LDWORK >= max(1,N);
085: *          if SIDE = 'R', LDWORK >= max(1,M).
086: *
087: *  INFO    (output) INTEGER
088: *          = 0:  successful exit
089: *          < 0:  if INFO = -i, the i-th argument had an illegal value
090: *
091: *  =====================================================================
092: *
093: *     .. Local Scalars ..
094:       LOGICAL            LEFT, NOTRAN
095:       INTEGER            I, I1, I2, I3, KB, IC, IINFO, JC,
096:      $                   MI, NI, NQ, NW
097: *     ..
098: *     .. External Functions ..
099:       LOGICAL            LSAME
100:       EXTERNAL           LSAME
101: *     ..
102: *     .. External Subroutines ..
103:       EXTERNAL           CLARFB, XERBLA
104: *     ..
105: *     .. Intrinsic Functions ..
106:       INTRINSIC          MAX, MIN
107: *     ..
108: *     .. Executable Statements ..
109: *
110: *     Test the input arguments
111: *
112:       INFO = 0
113:       LEFT = LSAME( SIDE, 'L' )
114:       NOTRAN = LSAME( TRANS, 'N' )
115: *
116: *     Quick return if possible
117: *
118:       IF( M.EQ.0 .OR. N.EQ.0 .OR. IB.EQ.0 .OR. K.EQ.0 ) THEN
119:          RETURN
120:       END IF
121: *
122: *     NQ is the order of Q and NW is the minimum dimension of WORK
123: *
124:       IF( LEFT ) THEN
125:          NQ = M
126:          NW = N
127:       ELSE
128:          NQ = N
129:          NW = M
130:       END IF
131:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
132:          INFO = -1
133:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
134:          INFO = -2
135:       ELSE IF( M.LT.0 ) THEN
136:          INFO = -3
137:       ELSE IF( N.LT.0 ) THEN
138:          INFO = -4
139:       ELSE IF( IB.LT.0 ) THEN
140:          INFO = -5
141:       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
142:          INFO = -6
143:       ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
144:          INFO = -8
145:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
146:          INFO = -12
147:       ELSE IF( LDWORK.LT.MAX( 1, NW ) ) THEN
148:          INFO = -14
149:       END IF
150: *
151:       IF( INFO.NE.0 ) THEN
152:          CALL XERBLA( 'CORE_CUNMQR', -INFO )
153:          RETURN
154:       END IF
155: *
156:       IF( ( LEFT .AND. .NOT.NOTRAN ) .OR.
157:      $    ( .NOT.LEFT .AND. NOTRAN ) ) THEN
158:          I1 = 1
159:          I2 = K
160:          I3 = IB
161:       ELSE
162:          I1 = ( ( K-1 ) / IB )*IB + 1
163:          I2 = 1
164:          I3 = -IB
165:       END IF
166: *
167:       IF( LEFT ) THEN
168:          NI = N
169:          JC = 1
170:       ELSE
171:          MI = M
172:          IC = 1
173:       END IF
174: *
175:       DO 10 I = I1, I2, I3
176:          KB = MIN( IB, K-I+1 )
177:          IF( LEFT ) THEN
178: *
179: *           H or H' is applied to C(i:m,1:n)
180: *
181:             MI = M - I + 1
182:             IC = I
183:          ELSE
184: *
185: *           H or H' is applied to C(1:m,i:n)
186: *
187:             NI = N - I + 1
188:             JC = I
189:          END IF
190: *
191: *        Apply H or H'
192: *
193:          CALL CLARFB( SIDE, TRANS, 'Forward', 'Columnwise', MI, NI,
194:      $               KB, A( I, I ), LDA, T( 1, I ), LDT,
195:      $               C( IC, JC ), LDC, WORK, LDWORK )
196:    10 CONTINUE
197:       RETURN
198: *
199: *     End of CORE_CUNMQR
200: *
201:       END
202: