001:       SUBROUTINE CORE_CUNMLQ( SIDE, TRANS, M, N, IB, K,  A, LDA,
002:      $                       T, LDT, C, LDC, WORK, LDWORK, INFO )
003: 
004: *********************************************************************
005: *     PLASMA core_blas routine (version 2.1.0)                      *
006: *     Author: Hatem Ltaief                                          *
007: *     Release Date: November, 15th 2009                             *
008: *     PLASMA is a software package provided by Univ. of Tennessee,  *
009: *     Univ. of California Berkeley and Univ. of Colorado Denver.    *
010: *********************************************************************
011: *
012: *     .. Scalar Arguments ..
013:       CHARACTER          SIDE, TRANS
014:       INTEGER            M, N, K, IB, INFO
015:       INTEGER            LDA, LDT, LDC, LDWORK
016: *     ..
017: *     .. Array Arguments ..
018:       COMPLEX            A( LDA, * ), C( LDC, * )
019:       COMPLEX            T( LDT, * ), WORK( LDWORK, * )
020: *     ..
021: *
022: *  Purpose
023: *  =======
024: *
025: *  CORE_CUNMLQ overwrites the general complex M-by-N tile C with
026: *
027: *                  SIDE = 'L'     SIDE = 'R'
028: *  TRANS = 'N':      Q * C          C * Q
029: *  TRANS = 'C':      Q**H * C       C * Q**H
030: *
031: *  where Q is a complex unitary matrix defined as the product of k
032: *  elementary reflectors
033: *
034: *        Q = H(k) . . . H(2) H(1)
035: *
036: *  as returned by CORE_CGELQT. Q is of order M if SIDE = 'L' and of order N
037: *  if SIDE = 'R'.
038: *
039: *  Arguments
040: *  =========
041: *
042: *  SIDE    (input) CHARACTER*1
043: *          = 'L': apply Q or Q**H from the Left;
044: *          = 'R': apply Q or Q**H from the Right.
045: *
046: *  TRANS   (input) CHARACTER*1
047: *          = 'N':  No transpose, apply Q;
048: *          = 'T':  Transpose, apply Q**H.
049: *
050: *  M       (input) INTEGER
051: *          The number of rows of the tile C. M >= 0.
052: *
053: *  N       (input) INTEGER
054: *          The number of columns of the tile C. N >= 0.
055: *
056: *  K       (input) INTEGER
057: *          The number of elementary reflectors whose product defines
058: *          the matrix Q.
059: *          If SIDE = 'L', M >= K >= 0;
060: *          if SIDE = 'R', N >= K >= 0.
061: *
062: *  A       (input) COMPLEX array, dimension
063: *                               (LDA,M) if SIDE = 'L',
064: *                               (LDA,N) if SIDE = 'R'
065: *          The i-th row must contain the vector which defines the
066: *          elementary reflector H(i), for i = 1,2,...,k, as returned by
067: *          CORE_CGELQT in the first k rows of its array argument A.
068: *
069: *  LDA     (input) INTEGER
070: *          The leading dimension of the array A. LDA >= max(1,K).
071: *
072: *  C       (input/output) COMPLEX array, dimension (LDC,N)
073: *          On entry, the M-by-N tile C.
074: *          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
075: *
076: *  LDC     (input) INTEGER
077: *          The leading dimension of the array C. LDC >= max(1,M).
078: *
079: *  WORK    (workspace/output) COMPLEX array, dimension (MAX(1,LDWORK))
080: *          On exit, if INFO = 0, WORK(1) returns the optimal LDWORK.
081: *
082: *  LDWORK   (input) INTEGER
083: *          The dimension of the array WORK.
084: *          If SIDE = 'L', LDWORK >= max(1,N);
085: *          if SIDE = 'R', LDWORK >= max(1,M).
086: *
087: *  INFO    (output) INTEGER
088: *          = 0:  successful exit
089: *          < 0:  if INFO = -i, the i-th argument had an illegal value
090: *
091: *  =====================================================================
092: *
093: *     .. Local Scalars ..
094:       LOGICAL            LEFT, NOTRAN
095:       CHARACTER          TRANST
096:       INTEGER            I, I1, I2, I3, KB, IC, IINFO, JC,
097:      $                   MI, NI, NQ, NW
098: *     ..
099: *     .. External Functions ..
100:       LOGICAL            LSAME
101:       EXTERNAL           LSAME
102: *     ..
103: *     .. External Subroutines ..
104:       EXTERNAL           CLARFB, XERBLA
105: *     ..
106: *     .. Intrinsic Functions ..
107:       INTRINSIC          MAX, MIN
108: *     ..
109: *     .. Executable Statements ..
110: *
111: *     Test the input arguments
112: *
113:       INFO = 0
114:       LEFT = LSAME( SIDE, 'L' )
115:       NOTRAN = LSAME( TRANS, 'N' )
116: *
117: *     Quick return if possible
118: *
119:       IF( M.EQ.0 .OR. N.EQ.0 .OR. K.EQ.0 ) THEN
120:          RETURN
121:       END IF
122: *
123: *     NQ is the order of Q and NW is the minimum dimension of WORK
124: *
125:       IF( LEFT ) THEN
126:          NQ = M
127:          NW = N
128:       ELSE
129:          NQ = N
130:          NW = M
131:       END IF
132:       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
133:          INFO = -1
134:       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
135:          INFO = -2
136:       ELSE IF( M.LT.0 ) THEN
137:          INFO = -3
138:       ELSE IF( N.LT.0 ) THEN
139:          INFO = -4
140:       ELSE IF( IB.LT.0 ) THEN
141:          INFO = -5
142:       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
143:          INFO = -6
144:       ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
145:          INFO = -7
146:       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
147:          INFO = -10
148:       ELSE IF( LDWORK.LT.MAX( 1, NW ) ) THEN
149:          INFO = -14
150:       END IF
151: *
152:       IF( INFO.NE.0 ) THEN
153:          CALL XERBLA( 'CORE_CUNMLQ', -INFO )
154:          RETURN
155:       END IF
156: 
157: *
158: 
159:       IF( ( LEFT .AND. NOTRAN ) .OR.
160:      $   ( .NOT.LEFT .AND. .NOT.NOTRAN ) ) THEN
161:          I1 = 1
162:          I2 = K
163:          I3 = IB
164:       ELSE
165:          I1 = ( ( K-1 ) / IB )*IB + 1
166:          I2 = 1
167:          I3 = -IB
168:       END IF
169: *
170:       IF( LEFT ) THEN
171:          NI = N
172:          JC = 1
173:       ELSE
174:          MI = M
175:          IC = 1
176:       END IF
177: *
178:       IF( NOTRAN ) THEN
179:          TRANST = 'C'
180:       ELSE
181:          TRANST = 'N'
182:       END IF
183: *
184:       DO 10 I = I1, I2, I3
185:          KB = MIN( IB, K-I+1 )
186: *
187:          IF( LEFT ) THEN
188: *
189: *           H or H' is applied to C(i:m,1:n)
190: *
191:             MI = M - I + 1
192:             IC = I
193:          ELSE
194: *
195: *           H or H' is applied to C(1:m,i:n)
196: *
197:             NI = N - I + 1
198:             JC = I
199:          END IF
200: *
201: *        Apply H or H'
202: *
203:          CALL CLARFB( SIDE, TRANST, 'Forward', 'Rowwise', MI, NI,
204:      $               KB, A( I, I ), LDA, T( 1, I ), LDT,
205:      $               C( IC, JC ), LDC, WORK, LDWORK )
206:    10 CONTINUE
207:       RETURN
208: *
209: *     End of CORE_CUNMLQ
210: *
211:       END
212: