clanhe.f

Go to the documentation of this file.

      REAL             FUNCTION clanhe( NORM, UPLO, N, A, LDA, WORK )
*
*  -- LAPACK auxiliary routine (version 3.2) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      CHARACTER          norm, uplo
      INTEGER            lda, n
*     ..
*     .. Array Arguments ..
      REAL               work( * )
      COMPLEX            a( lda, * )
*     ..
*
*  Purpose
*  =======
*
*  CLANHE  returns the value of the one norm,  or the Frobenius norm, or
*  the  infinity norm,  or the  element of  largest absolute value  of a
*  complex hermitian matrix A.
*
*  Description
*  ===========
*
*  CLANHE returns the value
*
*     CLANHE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
*              (
*              ( norm1(A),         NORM = '1', 'O' or 'o'
*              (
*              ( normI(A),         NORM = 'I' or 'i'
*              (
*              ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
*
*  where  norm1  denotes the  one norm of a matrix (maximum column sum),
*  normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
*  normF  denotes the  Frobenius norm of a matrix (square root of sum of
*  squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
*
*  Arguments
*  =========
*
*  NORM    (input) CHARACTER*1
*          Specifies the value to be returned in CLANHE as described
*          above.
*
*  UPLO    (input) CHARACTER*1
*          Specifies whether the upper or lower triangular part of the
*          hermitian matrix A is to be referenced.
*          = 'U':  Upper triangular part of A is referenced
*          = 'L':  Lower triangular part of A is referenced
*
*  N       (input) INTEGER
*          The order of the matrix A.  N >= 0.  When N = 0, CLANHE is
*          set to zero.
*
*  A       (input) COMPLEX array, dimension (LDA,N)
*          The hermitian matrix A.  If UPLO = 'U', the leading n by n
*          upper triangular part of A contains the upper triangular part
*          of the matrix A, and the strictly lower triangular part of A
*          is not referenced.  If UPLO = 'L', the leading n by n lower
*          triangular part of A contains the lower triangular part of
*          the matrix A, and the strictly upper triangular part of A is
*          not referenced. Note that the imaginary parts of the diagonal
*          elements need not be set and are assumed to be zero.
*
*  LDA     (input) INTEGER
*          The leading dimension of the array A.  LDA >= max(N,1).
*
*  WORK    (workspace) REAL array, dimension (MAX(1,LWORK)),
*          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
*          WORK is not referenced.
*
* =====================================================================
*
*     .. Parameters ..
      REAL               one, zero
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j
      REAL               absa, scale, sum, value
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           classq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, REAL, sqrt
*     ..
*     .. Executable Statements ..
*
      IF( n.EQ.0 ) THEN
         value = zero
      ELSE IF( lsame( norm, 'M' ) ) THEN
*
*        Find max(abs(A(i,j))).
*
         value = zero
         IF( lsame( uplo, 'U' ) ) THEN
            DO 20 j = 1, n
               DO 10 i = 1, j - 1
                  value = max( value, abs( a( i, j ) ) )
   10          continue
               value = max( value, abs( REAL( A( J, J ) ) ) )
   20       continue
         ELSE
            DO 40 j = 1, n
               value = max( value, abs( REAL( A( J, J ) ) ) )
               DO 30 i = j + 1, n
                  value = max( value, abs( a( i, j ) ) )
   30          continue
   40       continue
         END IF
      ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
     $         ( norm.EQ.'1' ) ) THEN
*
*        Find normI(A) ( = norm1(A), since A is hermitian).
*
         value = zero
         IF( lsame( uplo, 'U' ) ) THEN
            DO 60 j = 1, n
               sum = zero
               DO 50 i = 1, j - 1
                  absa = abs( a( i, j ) )
                  sum = sum + absa
                  work( i ) = work( i ) + absa
   50          continue
               work( j ) = sum + abs( REAL( A( J, J ) ) )
   60       continue
            DO 70 i = 1, n
               value = max( value, work( i ) )
   70       continue
         ELSE
            DO 80 i = 1, n
               work( i ) = zero
   80       continue
            DO 100 j = 1, n
               sum = work( j ) + abs( REAL( A( J, J ) ) )
               DO 90 i = j + 1, n
                  absa = abs( a( i, j ) )
                  sum = sum + absa
                  work( i ) = work( i ) + absa
   90          continue
               value = max( value, sum )
  100       continue
         END IF
      ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
*
*        Find normF(A).
*
         scale = zero
         sum = one
         IF( lsame( uplo, 'U' ) ) THEN
            DO 110 j = 2, n
               CALL classq( j-1, a( 1, j ), 1, scale, sum )
  110       continue
         ELSE
            DO 120 j = 1, n - 1
               CALL classq( n-j, a( j+1, j ), 1, scale, sum )
  120       continue
         END IF
         sum = 2*sum
         DO 130 i = 1, n
            IF( REAL( A( I, I ) ).NE.zero ) then
               absa = abs( REAL( A( I, I ) ) )
               IF( scale.LT.absa ) THEN
                  sum = one + sum*( scale / absa )**2
                  scale = absa
               ELSE
                  sum = sum + ( absa / scale )**2
               END IF
            END IF
  130    continue
         value = scale*sqrt( sum )
      END IF
*
      clanhe = value
      return
*
*     End of CLANHE
*
      END