test_zminMax.f

*> \brief zminMax tests the robustness and precision of the double-valued intrinsic operators MIN and MAX
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Authors:
*  ========
*
*> \author Weslley S. Pereira, University of Colorado Denver, U.S.
*
*> \verbatim
*>
*> Tests with pairs of numbers (x,y):
*> Inf inputs where x < y:
*>    (1) (-Inf,   0)
*>    (2) ( 0  , Inf)
*>    (3) (-Inf, Inf)
*> Inf inputs where x > y:
*>    (4) ( 0  ,-Inf)
*>    (5) ( Inf,   0)
*>    (6) ( Inf,-Inf)
*> NaN inputs to test NaN propagation:
*>    (7) ( 0  , NaN)
*>    (8) ( NaN,   0)
*> The program tests MIN(x,y) and MAX(x,y) for every pair
*>
*> \endverbatim
*
*> \ingroup auxOTHERauxiliary
*
*  =====================================================================
      program zmul
*
*  -- LAPACK test routine --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..

*     ..
*     .. Parameters ..
      integer           n
      parameter( n = 8 )
      double precision  zero
      parameter( zero = 0.0d0 )
*     ..
*     .. Local Variables ..
      integer           i
      double precision  ainf, anan, ov, r, x(n), y(n)
*
*     .. Intrinsic Functions ..
      intrinsic         huge, min, max

*
*     .. Inf and NaN entries ..
      ov = huge(0.0d0)
      ainf = ov * 2
      anan = ainf / ainf
      x = (/ -ainf, zero, -ainf,  zero, ainf,  ainf, zero, anan /)
      y = (/  zero, ainf,  ainf, -ainf, zero, -ainf, anan, zero /)

*
*     .. Tests ..
*
      do 10 i = 1, 3
          r = min( x(i), y(i) )
          if( r .ne. x(i) ) then
              WRITE( *, fmt = 9998 ) 'i',i, 'MIN', x(i), y(i), r
          endif
          r = max( x(i), y(i) )
          if( r .ne. y(i) ) then
              WRITE( *, fmt = 9998 ) 'i',i, 'MAX', x(i), y(i), r
          endif
  10  continue
      do 20 i = 4, 6
          r = min( x(i), y(i) )
          if( r .ne. y(i) ) then
              WRITE( *, fmt = 9998 ) 'i',i, 'MIN', x(i), y(i), r
          endif
          r = max( x(i), y(i) )
          if( r .ne. x(i) ) then
              WRITE( *, fmt = 9998 ) 'i',i, 'MAX', x(i), y(i), r
          endif
  20  continue
      do 30 i = 7, 8
          r = min( x(i), y(i) )
          if( r .eq. r ) then
              WRITE( *, fmt = 9998 ) 'i',i, 'MIN', x(i), y(i), r
          endif
          r = max( x(i), y(i) )
          if( r .eq. r ) then
              WRITE( *, fmt = 9998 ) 'i',i, 'MAX', x(i), y(i), r
          endif
  30  continue
*
*     .. Formats ..
 9998 FORMAT( '[',a1,i1, '] ', a3, '(', f5.0, ',', f5.0, ') = ', f5.0 )
*
*     End of zmul
*
      END