zqrt13.f

Go to the documentation of this file.

      SUBROUTINE zqrt13( SCALE, M, N, A, LDA, NORMA, ISEED )
*
*  -- LAPACK test routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      INTEGER            lda, m, n, scale
      DOUBLE PRECISION   norma
*     ..
*     .. Array Arguments ..
      INTEGER            iseed( 4 )
      COMPLEX*16         a( lda, * )
*     ..
*
*  Purpose
*  =======
*
*  ZQRT13 generates a full-rank matrix that may be scaled to have large
*  or small norm.
*
*  Arguments
*  =========
*
*  SCALE   (input) INTEGER
*          SCALE = 1: normally scaled matrix
*          SCALE = 2: matrix scaled up
*          SCALE = 3: matrix scaled down
*
*  M       (input) INTEGER
*          The number of rows of the matrix A.
*
*  N       (input) INTEGER
*          The number of columns of A.
*
*  A       (output) COMPLEX*16 array, dimension (LDA,N)
*          The M-by-N matrix A.
*
*  LDA     (input) INTEGER
*          The leading dimension of the array A.
*
*  NORMA   (output) DOUBLE PRECISION
*          The one-norm of A.
*
*  ISEED   (input/output) integer array, dimension (4)
*          Seed for random number generator
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one
      parameter( one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            info, j
      DOUBLE PRECISION   bignum, smlnum
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, dzasum, zlange
      EXTERNAL           dlamch, dzasum, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlabad, zlarnv, zlascl
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, sign
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   dummy( 1 )
*     ..
*     .. Executable Statements ..
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   return
*
*     benign matrix
*
      DO 10 j = 1, n
         CALL zlarnv( 2, iseed, m, a( 1, j ) )
         IF( j.LE.m ) THEN
            a( j, j ) = a( j, j ) + dcmplx( sign( dzasum( m, a( 1, j ),
     $                  1 ), dble( a( j, j ) ) ) )
         END IF
   10 continue
*
*     scaled versions
*
      IF( scale.NE.1 ) THEN
         norma = zlange( 'Max', m, n, a, lda, dummy )
         smlnum = dlamch( 'Safe minimum' )
         bignum = one / smlnum
         CALL dlabad( smlnum, bignum )
         smlnum = smlnum / dlamch( 'Epsilon' )
         bignum = one / smlnum
*
         IF( scale.EQ.2 ) THEN
*
*           matrix scaled up
*
            CALL zlascl( 'General', 0, 0, norma, bignum, m, n, a, lda,
     $                   info )
         ELSE IF( scale.EQ.3 ) THEN
*
*           matrix scaled down
*
            CALL zlascl( 'General', 0, 0, norma, smlnum, m, n, a, lda,
     $                   info )
         END IF
      END IF
*
      norma = zlange( 'One-norm', m, n, a, lda, dummy )
      return
*
*     End of ZQRT13
*
      END