zpot01.f

Go to the documentation of this file.

      SUBROUTINE zpot01( UPLO, N, A, LDA, AFAC, LDAFAC, RWORK, RESID )
*
*  -- LAPACK test routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            lda, ldafac, n
      DOUBLE PRECISION   resid
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   rwork( * )
      COMPLEX*16         a( lda, * ), afac( ldafac, * )
*     ..
*
*  Purpose
*  =======
*
*  ZPOT01 reconstructs a Hermitian positive definite matrix  A  from
*  its L*L' or U'*U factorization and computes the residual
*     norm( L*L' - A ) / ( N * norm(A) * EPS ) or
*     norm( U'*U - A ) / ( N * norm(A) * EPS ),
*  where EPS is the machine epsilon, L' is the conjugate transpose of L,
*  and U' is the conjugate transpose of U.
*
*  Arguments
*  ==========
*
*  UPLO    (input) CHARACTER*1
*          Specifies whether the upper or lower triangular part of the
*          Hermitian matrix A is stored:
*          = 'U':  Upper triangular
*          = 'L':  Lower triangular
*
*  N       (input) INTEGER
*          The number of rows and columns of the matrix A.  N >= 0.
*
*  A       (input) COMPLEX*16 array, dimension (LDA,N)
*          The original Hermitian matrix A.
*
*  LDA     (input) INTEGER
*          The leading dimension of the array A.  LDA >= max(1,N)
*
*  AFAC    (input/output) COMPLEX*16 array, dimension (LDAFAC,N)
*          On entry, the factor L or U from the L*L' or U'*U
*          factorization of A.
*          Overwritten with the reconstructed matrix, and then with the
*          difference L*L' - A (or U'*U - A).
*
*  LDAFAC  (input) INTEGER
*          The leading dimension of the array AFAC.  LDAFAC >= max(1,N).
*
*  RWORK   (workspace) DOUBLE PRECISION array, dimension (N)
*
*  RESID   (output) DOUBLE PRECISION
*          If UPLO = 'L', norm(L*L' - A) / ( N * norm(A) * EPS )
*          If UPLO = 'U', norm(U'*U - A) / ( N * norm(A) * EPS )
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j, k
      DOUBLE PRECISION   anorm, eps, tr
      COMPLEX*16         tc
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      DOUBLE PRECISION   dlamch, zlanhe
      COMPLEX*16         zdotc
      EXTERNAL           lsame, dlamch, zlanhe, zdotc
*     ..
*     .. External Subroutines ..
      EXTERNAL           zher, zscal, ztrmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dimag
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         resid = zero
         return
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = dlamch( 'Epsilon' )
      anorm = zlanhe( '1', uplo, n, a, lda, rwork )
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         return
      END IF
*
*     Check the imaginary parts of the diagonal elements and return with
*     an error code if any are nonzero.
*
      DO 10 j = 1, n
         IF( dimag( afac( j, j ) ).NE.zero ) THEN
            resid = one / eps
            return
         END IF
   10 continue
*
*     Compute the product U'*U, overwriting U.
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 20 k = n, 1, -1
*
*           Compute the (K,K) element of the result.
*
            tr = zdotc( k, afac( 1, k ), 1, afac( 1, k ), 1 )
            afac( k, k ) = tr
*
*           Compute the rest of column K.
*
            CALL ztrmv( 'Upper', 'Conjugate', 'Non-unit', k-1, afac,
     $                  ldafac, afac( 1, k ), 1 )
*
   20    continue
*
*     Compute the product L*L', overwriting L.
*
      ELSE
         DO 30 k = n, 1, -1
*
*           Add a multiple of column K of the factor L to each of
*           columns K+1 through N.
*
            IF( k+1.LE.n )
     $         CALL zher( 'Lower', n-k, one, afac( k+1, k ), 1,
     $                    afac( k+1, k+1 ), ldafac )
*
*           Scale column K by the diagonal element.
*
            tc = afac( k, k )
            CALL zscal( n-k+1, tc, afac( k, k ), 1 )
*
   30    continue
      END IF
*
*     Compute the difference  L*L' - A (or U'*U - A).
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 50 j = 1, n
            DO 40 i = 1, j - 1
               afac( i, j ) = afac( i, j ) - a( i, j )
   40       continue
            afac( j, j ) = afac( j, j ) - dble( a( j, j ) )
   50    continue
      ELSE
         DO 70 j = 1, n
            afac( j, j ) = afac( j, j ) - dble( a( j, j ) )
            DO 60 i = j + 1, n
               afac( i, j ) = afac( i, j ) - a( i, j )
   60       continue
   70    continue
      END IF
*
*     Compute norm( L*U - A ) / ( N * norm(A) * EPS )
*
      resid = zlanhe( '1', uplo, n, afac, ldafac, rwork )
*
      resid = ( ( resid / dble( n ) ) / anorm ) / eps
*
      return
*
*     End of ZPOT01
*
      END