zlqt03.f

Go to the documentation of this file.

      SUBROUTINE zlqt03( M, N, K, AF, C, CC, Q, LDA, T, WORK, LWORK,
     $                   rwork, result )
*
      include 'plasmaf.h'
*
*  -- LAPACK test routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      INTEGER            k, lda, lwork, m, n
      INTEGER            t( 2 )
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   result( * ), rwork( * )
      COMPLEX*16         af( lda, * ), c( lda, * ), cc( lda, * ),
     $                   q( lda, * ), work( lwork )
*     ..
*
*  Purpose
*  =======
*
*  ZLQT03 tests ZUNMLQ, which computes Q*C, Q'*C, C*Q or C*Q'.
*
*  ZLQT03 compares the results of a call to ZUNMLQ with the results of
*  forming Q explicitly by a call to ZUNGLQ and then performing matrix
*  multiplication by a call to ZGEMM.
*
*  Arguments
*  =========
*
*  M       (input) INTEGER
*          The number of rows or columns of the matrix C; C is n-by-m if
*          Q is applied from the left, or m-by-n if Q is applied from
*          the right.  M >= 0.
*
*  N       (input) INTEGER
*          The order of the orthogonal matrix Q.  N >= 0.
*
*  K       (input) INTEGER
*          The number of elementary reflectors whose product defines the
*          orthogonal matrix Q.  N >= K >= 0.
*
*  AF      (input) COMPLEX*16 array, dimension (LDA,N)
*          Details of the LQ factorization of an m-by-n matrix, as
*          returned by ZGELQF. See CGELQF for further details.
*
*  C       (workspace) COMPLEX*16 array, dimension (LDA,N)
*
*  CC      (workspace) COMPLEX*16 array, dimension (LDA,N)
*
*  Q       (workspace) COMPLEX*16 array, dimension (LDA,N)
*
*  LDA     (input) INTEGER
*          The leading dimension of the arrays AF, C, CC, and Q.
*
*  TAU     (input) COMPLEX*16 array, dimension (min(M,N))
*          The scalar factors of the elementary reflectors corresponding
*          to the LQ factorization in AF.
*
*  WORK    (workspace) COMPLEX*16 array, dimension (LWORK)
*
*  LWORK   (input) INTEGER
*          The length of WORK.  LWORK must be at least M, and should be
*          M*NB, where NB is the blocksize for this environment.
*
*  RWORK   (workspace) DOUBLE PRECISION array, dimension (M)
*
*  RESULT  (output) DOUBLE PRECISION array, dimension (4)
*          The test ratios compare two techniques for multiplying a
*          random matrix C by an n-by-n orthogonal matrix Q.
*          RESULT(1) = norm( Q*C - Q*C )  / ( N * norm(C) * EPS )
*          RESULT(2) = norm( C*Q - C*Q )  / ( N * norm(C) * EPS )
*          RESULT(3) = norm( Q'*C - Q'*C )/ ( N * norm(C) * EPS )
*          RESULT(4) = norm( C*Q' - C*Q' )/ ( N * norm(C) * EPS )
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         rogue
      parameter( rogue = ( -1.0d+10, -1.0d+10 ) )
*     ..
*     .. Local Scalars ..
      CHARACTER          side, trans
      INTEGER            info, iside, itrans, j, mc, nc
      INTEGER            plasma_side, plasma_trans
      DOUBLE PRECISION   cnorm, eps, resid
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      DOUBLE PRECISION   dlamch, zlange
      EXTERNAL           lsame, dlamch, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemm, zlacpy, zlarnv, zlaset, zunglq, zunmlq
*     ..
*     .. Local Arrays ..
      INTEGER            iseed( 4 )
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, max
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       srnamt
*     ..
*     .. Common blocks ..
      common             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseed / 1988, 1989, 1990, 1991 /
*     ..
*     .. Executable Statements ..
*
      eps = dlamch( 'Epsilon' )
*
*     Copy the first k rows of the factorization to the array Q
*
      IF ( k.EQ.0 ) THEN
          CALL zlaset( 'Full', n, n, rogue, rogue, q, lda )
      ELSE
          CALL zlaset( 'Full', n, n, dcmplx( zero ), dcmplx( one ),
     $                 q, lda )
      ENDIF
*
*     Generate the n-by-n matrix Q
*
      srnamt = 'ZUNGLQ'
      CALL plasma_zunglq( n, n, k, af, lda, t, q, lda, info )
*
      DO 30 iside = 1, 2
         IF( iside.EQ.1 ) THEN
            side = 'L'
            plasma_side = plasmaleft
            mc = n
            nc = m
         ELSE
            side = 'R'
            plasma_side = plasmaright
            mc = m
            nc = n
         END IF
*
*        Generate MC by NC matrix C
*
         DO 10 j = 1, nc
            CALL zlarnv( 2, iseed, mc, c( 1, j ) )
   10    continue
         cnorm = zlange( '1', mc, nc, c, lda, rwork )
         IF( cnorm.EQ.zero )
     $      cnorm = one
*
         DO 20 itrans = 1, 2
            IF( itrans.EQ.1 ) THEN
               plasma_trans = plasmanotrans
               trans = 'N'
            ELSE
               trans = 'C'
               plasma_trans = plasmaconjtrans
            END IF
*
*           Copy C
*
            CALL zlacpy( 'Full', mc, nc, c, lda, cc, lda )
*
*           Apply Q or Q' to C
*
            srnamt = 'ZUNMLQ'
            CALL plasma_zunmlq( plasma_side, plasma_trans, mc, nc, k,
     $                   af, lda, t, cc, lda, info )
*
*           Form explicit product and subtract
*
            IF ( k.EQ.0 ) THEN
               CALL zlaset( 'Full', n, n, dcmplx( zero ),
     $              dcmplx( one ), q, lda )
            ENDIF
            IF( lsame( side, 'L' ) ) THEN
               CALL zgemm( trans, 'No transpose', mc, nc, mc,
     $                     dcmplx( -one ), q, lda, c, lda,
     $                     dcmplx( one ), cc, lda )
            ELSE
               CALL zgemm( 'No transpose', trans, mc, nc, nc,
     $                     dcmplx( -one ), c, lda, q, lda,
     $                     dcmplx( one ), cc, lda )
            END IF
*
*           Compute error in the difference
*
            resid = zlange( '1', mc, nc, cc, lda, rwork )
            result( ( iside-1 )*2+itrans ) = resid /
     $         ( dble( max( 1, n ) )*cnorm*eps )
*
   20    continue
   30 continue
*
      return
*
*     End of ZLQT03
*
      END