zlqt02.f

Go to the documentation of this file.

      SUBROUTINE zlqt02( M, N, K, A, AF, Q, L, LDA, T, WORK, LWORK,
     $                   rwork, result )
*
      include 'plasmaf.h'
*
*  -- LAPACK test routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      INTEGER            k, lda, lwork, m, n
      INTEGER            t( 2 )
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   result( * ), rwork( * )
      COMPLEX*16         a( lda, * ), af( lda, * ), l( lda, * ),
     $                   q( lda, * ), work( lwork )
*     ..
*
*  Purpose
*  =======
*
*  ZLQT02 tests ZUNGLQ, which generates an m-by-n matrix Q with
*  orthonornmal rows that is defined as the product of k elementary
*  reflectors.
*
*  Given the LQ factorization of an m-by-n matrix A, ZLQT02 generates
*  the orthogonal matrix Q defined by the factorization of the first k
*  rows of A; it compares L(1:k,1:m) with A(1:k,1:n)*Q(1:m,1:n)', and
*  checks that the rows of Q are orthonormal.
*
*  Arguments
*  =========
*
*  M       (input) INTEGER
*          The number of rows of the matrix Q to be generated.  M >= 0.
*
*  N       (input) INTEGER
*          The number of columns of the matrix Q to be generated.
*          N >= M >= 0.
*
*  K       (input) INTEGER
*          The number of elementary reflectors whose product defines the
*          matrix Q. M >= K >= 0.
*
*  A       (input) COMPLEX*16 array, dimension (LDA,N)
*          The m-by-n matrix A which was factorized by ZLQT01.
*
*  AF      (input) COMPLEX*16 array, dimension (LDA,N)
*          Details of the LQ factorization of A, as returned by ZGELQF.
*          See ZGELQF for further details.
*
*  Q       (workspace) COMPLEX*16 array, dimension (LDA,N)
*
*  L       (workspace) COMPLEX*16 array, dimension (LDA,M)
*
*  LDA     (input) INTEGER
*          The leading dimension of the arrays A, AF, Q and L. LDA >= N.
*
*  TAU     (input) COMPLEX*16 array, dimension (M)
*          The scalar factors of the elementary reflectors corresponding
*          to the LQ factorization in AF.
*
*  WORK    (workspace) COMPLEX*16 array, dimension (LWORK)
*
*  LWORK   (input) INTEGER
*          The dimension of the array WORK.
*
*  RWORK   (workspace) DOUBLE PRECISION array, dimension (M)
*
*  RESULT  (output) DOUBLE PRECISION array, dimension (2)
*          The test ratios:
*          RESULT(1) = norm( L - A*Q' ) / ( N * norm(A) * EPS )
*          RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         rogue
      parameter( rogue = ( -1.0d+10, -1.0d+10 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            info
      DOUBLE PRECISION   anorm, eps, resid
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, zlange, zlansy
      EXTERNAL           dlamch, zlange, zlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemm, zherk, zlacpy, zlaset, zunglq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, max
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       srnamt
*     ..
*     .. Common blocks ..
      common             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      eps = dlamch( 'Epsilon' )
*
*     Copy the first k rows of the factorization to the array Q
*
      CALL zlaset( 'Full', m, n, dcmplx( zero ), dcmplx( one ), q, lda )
*
*     Generate the first n columns of the matrix Q
*
      srnamt = 'ZUNGLQ'
      CALL plasma_zunglq( m, n, k, af, lda, t, q, lda, info )
*
*     Copy L(1:k,1:m)
*
      CALL zlaset( 'Full', k, m, dcmplx( zero ), dcmplx( zero ), l,
     $             lda )
      CALL zlacpy( 'Lower', k, m, af, lda, l, lda )
*
*     Compute L(1:k,1:m) - A(1:k,1:n) * Q(1:m,1:n)'
*
      CALL zgemm( 'No transpose', 'Conjugate transpose', k, m, n,
     $            dcmplx( -one ), a, lda, q, lda, dcmplx( one ), l,
     $            lda )
*
*     Compute norm( L - A*Q' ) / ( N * norm(A) * EPS ) .
*
      anorm = zlange( '1', k, n, a, lda, rwork )
      resid = zlange( '1', k, m, l, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / dble( max( 1, n ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL zlaset( 'Full', m, m, dcmplx( zero ), dcmplx( one ), l, lda )
      CALL zherk( 'Upper', 'No transpose', m, n, -one, q, lda, one, l,
     $            lda )
*
*     Compute norm( I - Q*Q' ) / ( N * EPS ) .
*
      resid = zlansy( '1', 'Upper', m, l, lda, rwork )
*
      result( 2 ) = ( resid / dble( max( 1, n ) ) ) / eps
*
      return
*
*     End of ZLQT02
*
      END