zlqt01.f

Go to the documentation of this file.

      SUBROUTINE zlqt01( M, N, A, AF, Q, L, LDA, T, WORK, LWORK,
     $                   rwork, result )
*
      include 'plasmaf.h'
*
*  -- LAPACK test routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      INTEGER            lda, lwork, m, n
      INTEGER            t( 2 )
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   result( * ), rwork( * )
      COMPLEX*16         a( lda, * ), af( lda, * ), l( lda, * ),
     $                   q( lda, * ), work( lwork )
*     ..
*
*  Purpose
*  =======
*
*  ZLQT01 tests ZGELQF, which computes the LQ factorization of an m-by-n
*  matrix A, and partially tests ZUNGLQ which forms the n-by-n
*  orthogonal matrix Q.
*
*  ZLQT01 compares L with A*Q', and checks that Q is orthogonal.
*
*  Arguments
*  =========
*
*  M       (input) INTEGER
*          The number of rows of the matrix A.  M >= 0.
*
*  N       (input) INTEGER
*          The number of columns of the matrix A.  N >= 0.
*
*  A       (input) COMPLEX*16 array, dimension (LDA,N)
*          The m-by-n matrix A.
*
*  AF      (output) COMPLEX*16 array, dimension (LDA,N)
*          Details of the LQ factorization of A, as returned by ZGELQF.
*          See ZGELQF for further details.
*
*  Q       (output) COMPLEX*16 array, dimension (LDA,N)
*          The n-by-n orthogonal matrix Q.
*
*  L       (workspace) COMPLEX*16 array, dimension (LDA,max(M,N))
*
*  LDA     (input) INTEGER
*          The leading dimension of the arrays A, AF, Q and L.
*          LDA >= max(M,N).
*
*  TAU     (output) COMPLEX*16 array, dimension (min(M,N))
*          The scalar factors of the elementary reflectors, as returned
*          by ZGELQF.
*
*  WORK    (workspace) COMPLEX*16 array, dimension (LWORK)
*
*  LWORK   (input) INTEGER
*          The dimension of the array WORK.
*
*  RWORK   (workspace) DOUBLE PRECISION array, dimension (max(M,N))
*
*  RESULT  (output) DOUBLE PRECISION array, dimension (2)
*          The test ratios:
*          RESULT(1) = norm( L - A*Q' ) / ( N * norm(A) * EPS )
*          RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         rogue
      parameter( rogue = ( -1.0d+10, -1.0d+10 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            info, minmn
      DOUBLE PRECISION   anorm, eps, resid
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, zlange, zlansy
      EXTERNAL           dlamch, zlange, zlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgelqf, zgemm, zherk, zlacpy, zlaset, zunglq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, max, min
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       srnamt
*     ..
*     .. Common blocks ..
      common             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      minmn = min( m, n )
      eps = dlamch( 'Epsilon' )
*
*     Copy the matrix A to the array AF.
*
      CALL zlacpy( 'Full', m, n, a, lda, af, lda )
*
*     Factorize the matrix A in the array AF.
*
      srnamt = 'ZGELQF'
      CALL plasma_zgelqf( m, n, af, lda, t, info )
*
*     Copy details of Q
*
      CALL zlaset( 'Full', m, n, dcmplx( zero ), dcmplx( one ), q, lda )
*
*     Generate the n-by-n matrix Q
*
      srnamt = 'ZUNGLQ'
      CALL plasma_zunglq( m, n, minmn, af, lda, t, q, lda, info )
*
*     Copy L
*
      CALL zlaset( 'Full', m, m, dcmplx( zero ), dcmplx( zero ), l,
     $             lda )
      CALL zlacpy( 'Lower', m, n, af, lda, l, lda )
*
*     Compute L - A*Q'
*
      CALL zgemm( 'No transpose', 'Conjugate transpose', m, m, n,
     $            dcmplx( -one ), a, lda, q, lda, dcmplx( one ), l,
     $            lda )
*
*     Compute norm( L - Q'*A ) / ( N * norm(A) * EPS ) .
*
      anorm = zlange( '1', m, n, a, lda, rwork )
      resid = zlange( '1', m, m, l, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / dble( max( 1, n ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL zlaset( 'Full', m, m, dcmplx( zero ), dcmplx( one ), l, lda )
      CALL zherk( 'Upper', 'No transpose', m, n, one, q, lda, -one, l,
     $            lda )
*
*     Compute norm( I - Q*Q' ) / ( N * EPS ) .
*
      resid = zlansy( '1', 'Upper', m, l, lda, rwork )
*
      result( 2 ) = ( resid / dble( max( 1, m ) ) ) / eps
*
      return
*
*     End of ZLQT01
*
      END