zlaqge.f

Go to the documentation of this file.

      SUBROUTINE zlaqge( M, N, A, LDA, R, C, ROWCND, COLCND, AMAX,
     $                   equed )
*
*  -- LAPACK auxiliary routine (version 3.2) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      CHARACTER          equed
      INTEGER            lda, m, n
      DOUBLE PRECISION   amax, colcnd, rowcnd
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   c( * ), r( * )
      COMPLEX*16         a( lda, * )
*     ..
*
*  Purpose
*  =======
*
*  ZLAQGE equilibrates a general M by N matrix A using the row and
*  column scaling factors in the vectors R and C.
*
*  Arguments
*  =========
*
*  M       (input) INTEGER
*          The number of rows of the matrix A.  M >= 0.
*
*  N       (input) INTEGER
*          The number of columns of the matrix A.  N >= 0.
*
*  A       (input/output) COMPLEX*16 array, dimension (LDA,N)
*          On entry, the M by N matrix A.
*          On exit, the equilibrated matrix.  See EQUED for the form of
*          the equilibrated matrix.
*
*  LDA     (input) INTEGER
*          The leading dimension of the array A.  LDA >= max(M,1).
*
*  R       (input) DOUBLE PRECISION array, dimension (M)
*          The row scale factors for A.
*
*  C       (input) DOUBLE PRECISION array, dimension (N)
*          The column scale factors for A.
*
*  ROWCND  (input) DOUBLE PRECISION
*          Ratio of the smallest R(i) to the largest R(i).
*
*  COLCND  (input) DOUBLE PRECISION
*          Ratio of the smallest C(i) to the largest C(i).
*
*  AMAX    (input) DOUBLE PRECISION
*          Absolute value of largest matrix entry.
*
*  EQUED   (output) CHARACTER*1
*          Specifies the form of equilibration that was done.
*          = 'N':  No equilibration
*          = 'R':  Row equilibration, i.e., A has been premultiplied by
*                  diag(R).
*          = 'C':  Column equilibration, i.e., A has been postmultiplied
*                  by diag(C).
*          = 'B':  Both row and column equilibration, i.e., A has been
*                  replaced by diag(R) * A * diag(C).
*
*  Internal Parameters
*  ===================
*
*  THRESH is a threshold value used to decide if row or column scaling
*  should be done based on the ratio of the row or column scaling
*  factors.  If ROWCND < THRESH, row scaling is done, and if
*  COLCND < THRESH, column scaling is done.
*
*  LARGE and SMALL are threshold values used to decide if row scaling
*  should be done based on the absolute size of the largest matrix
*  element.  If AMAX > LARGE or AMAX < SMALL, row scaling is done.
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one, thresh
      parameter( one = 1.0d+0, thresh = 0.1d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j
      DOUBLE PRECISION   cj, large, small
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch
      EXTERNAL           dlamch
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 ) THEN
         equed = 'N'
         return
      END IF
*
*     Initialize LARGE and SMALL.
*
      small = dlamch( 'Safe minimum' ) / dlamch( 'Precision' )
      large = one / small
*
      IF( rowcnd.GE.thresh .AND. amax.GE.small .AND. amax.LE.large )
     $     THEN
*
*        No row scaling
*
         IF( colcnd.GE.thresh ) THEN
*
*           No column scaling
*
            equed = 'N'
         ELSE
*
*           Column scaling
*
            DO 20 j = 1, n
               cj = c( j )
               DO 10 i = 1, m
                  a( i, j ) = cj*a( i, j )
   10          continue
   20       continue
            equed = 'C'
         END IF
      ELSE IF( colcnd.GE.thresh ) THEN
*
*        Row scaling, no column scaling
*
         DO 40 j = 1, n
            DO 30 i = 1, m
               a( i, j ) = r( i )*a( i, j )
   30       continue
   40    continue
         equed = 'R'
      ELSE
*
*        Row and column scaling
*
         DO 60 j = 1, n
            cj = c( j )
            DO 50 i = 1, m
               a( i, j ) = cj*r( i )*a( i, j )
   50       continue
   60    continue
         equed = 'B'
      END IF
*
      return
*
*     End of ZLAQGE
*
      END