sqrt15.f

Go to the documentation of this file.

      SUBROUTINE sqrt15( SCALE, RKSEL, M, N, NRHS, A, LDA, B, LDB, S,
     $                   rank, norma, normb, iseed, work, lwork )
*
*  -- LAPACK test routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      INTEGER            lda, ldb, lwork, m, n, nrhs, rank, rksel, scale
      REAL               norma, normb
*     ..
*     .. Array Arguments ..
      INTEGER            iseed( 4 )
      REAL               a( lda, * ), b( ldb, * ), s( * ), work( lwork )
*     ..
*
*  Purpose
*  =======
*
*  SQRT15 generates a matrix with full or deficient rank and of various
*  norms.
*
*  Arguments
*  =========
*
*  SCALE   (input) INTEGER
*          SCALE = 1: normally scaled matrix
*          SCALE = 2: matrix scaled up
*          SCALE = 3: matrix scaled down
*
*  RKSEL   (input) INTEGER
*          RKSEL = 1: full rank matrix
*          RKSEL = 2: rank-deficient matrix
*
*  M       (input) INTEGER
*          The number of rows of the matrix A.
*
*  N       (input) INTEGER
*          The number of columns of A.
*
*  NRHS    (input) INTEGER
*          The number of columns of B.
*
*  A       (output) REAL array, dimension (LDA,N)
*          The M-by-N matrix A.
*
*  LDA     (input) INTEGER
*          The leading dimension of the array A.
*
*  B       (output) REAL array, dimension (LDB, NRHS)
*          A matrix that is in the range space of matrix A.
*
*  LDB     (input) INTEGER
*          The leading dimension of the array B.
*
*  S       (output) REAL array, dimension MIN(M,N)
*          Singular values of A.
*
*  RANK    (output) INTEGER
*          number of nonzero singular values of A.
*
*  NORMA   (output) REAL
*          one-norm of A.
*
*  NORMB   (output) REAL
*          one-norm of B.
*
*  ISEED   (input/output) integer array, dimension (4)
*          seed for random number generator.
*
*  WORK    (workspace) REAL array, dimension (LWORK)
*
*  LWORK   (input) INTEGER
*          length of work space required.
*          LWORK >= MAX(M+MIN(M,N),NRHS*MIN(M,N),2*N+M)
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one, two, svmin
      parameter( zero = 0.0e0, one = 1.0e0, two = 2.0e0,
     $                   svmin = 0.1e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            info, j, mn
      REAL               bignum, eps, smlnum, temp
*     ..
*     .. Local Arrays ..
      REAL               dummy( 1 )
*     ..
*     .. External Functions ..
      REAL               sasum, slamch, slange, slarnd, snrm2
      EXTERNAL           sasum, slamch, slange, slarnd, snrm2
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, slaord, slarf, slarnv, slaror, slascl,
     $                   slaset, sscal, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min
*     ..
*     .. Executable Statements ..
*
      mn = min( m, n )
      IF( lwork.LT.max( m+mn, mn*nrhs, 2*n+m ) ) THEN
         CALL xerbla( 'SQRT15', 16 )
         return
      END IF
*
      smlnum = slamch( 'Safe minimum' )
      bignum = one / smlnum
      eps = slamch( 'Epsilon' )
      smlnum = ( smlnum / eps ) / eps
      bignum = one / smlnum
*
*     Determine rank and (unscaled) singular values
*
      IF( rksel.EQ.1 ) THEN
         rank = mn
      ELSE IF( rksel.EQ.2 ) THEN
         rank = ( 3*mn ) / 4
         DO 10 j = rank + 1, mn
            s( j ) = zero
   10    continue
      ELSE
         CALL xerbla( 'SQRT15', 2 )
      END IF
*
      IF( rank.GT.0 ) THEN
*
*        Nontrivial case
*
         s( 1 ) = one
         DO 30 j = 2, rank
   20       continue
            temp = slarnd( 1, iseed )
            IF( temp.GT.svmin ) THEN
               s( j ) = abs( temp )
            ELSE
               go to 20
            END IF
   30    continue
         CALL slaord( 'Decreasing', rank, s, 1 )
*
*        Generate 'rank' columns of a random orthogonal matrix in A
*
         CALL slarnv( 2, iseed, m, work )
         CALL sscal( m, one / snrm2( m, work, 1 ), work, 1 )
         CALL slaset( 'Full', m, rank, zero, one, a, lda )
         CALL slarf( 'Left', m, rank, work, 1, two, a, lda,
     $               work( m+1 ) )
*
*        workspace used: m+mn
*
*        Generate consistent rhs in the range space of A
*
         CALL slarnv( 2, iseed, rank*nrhs, work )
         CALL sgemm( 'No transpose', 'No transpose', m, nrhs, rank, one,
     $               a, lda, work, rank, zero, b, ldb )
*
*        work space used: <= mn *nrhs
*
*        generate (unscaled) matrix A
*
         DO 40 j = 1, rank
            CALL sscal( m, s( j ), a( 1, j ), 1 )
   40    continue
         IF( rank.LT.n )
     $      CALL slaset( 'Full', m, n-rank, zero, zero, a( 1, rank+1 ),
     $                   lda )
         CALL slaror( 'Right', 'No initialization', m, n, a, lda, iseed,
     $                work, info )
*
      ELSE
*
*        work space used 2*n+m
*
*        Generate null matrix and rhs
*
         DO 50 j = 1, mn
            s( j ) = zero
   50    continue
         CALL slaset( 'Full', m, n, zero, zero, a, lda )
         CALL slaset( 'Full', m, nrhs, zero, zero, b, ldb )
*
      END IF
*
*     Scale the matrix
*
      IF( scale.NE.1 ) THEN
         norma = slange( 'Max', m, n, a, lda, dummy )
         IF( norma.NE.zero ) THEN
            IF( scale.EQ.2 ) THEN
*
*              matrix scaled up
*
               CALL slascl( 'General', 0, 0, norma, bignum, m, n, a,
     $                      lda, info )
               CALL slascl( 'General', 0, 0, norma, bignum, mn, 1, s,
     $                      mn, info )
               CALL slascl( 'General', 0, 0, norma, bignum, m, nrhs, b,
     $                      ldb, info )
            ELSE IF( scale.EQ.3 ) THEN
*
*              matrix scaled down
*
               CALL slascl( 'General', 0, 0, norma, smlnum, m, n, a,
     $                      lda, info )
               CALL slascl( 'General', 0, 0, norma, smlnum, mn, 1, s,
     $                      mn, info )
               CALL slascl( 'General', 0, 0, norma, smlnum, m, nrhs, b,
     $                      ldb, info )
            ELSE
               CALL xerbla( 'SQRT15', 1 )
               return
            END IF
         END IF
      END IF
*
      norma = sasum( mn, s, 1 )
      normb = slange( 'One-norm', m, nrhs, b, ldb, dummy )
*
      return
*
*     End of SQRT15
*
      END