sqrt03.f

Go to the documentation of this file.

      SUBROUTINE sqrt03( M, N, K, AF, C, CC, Q, LDA, T, WORK, LWORK,
     $                   rwork, result )
*
      include 'plasmaf.h'
*
*  -- LAPACK test routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      INTEGER            k, lda, lwork, m, n
      INTEGER            t( 2 )
*     ..
*     .. Array Arguments ..
      REAL               af( lda, * ), c( lda, * ), cc( lda, * ),
     $                   q( lda, * ), result( * ), rwork( * ), 
     $                   work( lwork )
*     ..
*
*  Purpose
*  =======
*
*  SQRT03 tests SORMQR, which computes Q*C, Q'*C, C*Q or C*Q'.
*
*  SQRT03 compares the results of a call to SORMQR with the results of
*  forming Q explicitly by a call to SORGQR and then performing matrix
*  multiplication by a call to SGEMM.
*
*  Arguments
*  =========
*
*  M       (input) INTEGER
*          The order of the orthogonal matrix Q.  M >= 0.
*
*  N       (input) INTEGER
*          The number of rows or columns of the matrix C; C is m-by-n if
*          Q is applied from the left, or n-by-m if Q is applied from
*          the right.  N >= 0.
*
*  K       (input) INTEGER
*          The number of elementary reflectors whose product defines the
*          orthogonal matrix Q.  M >= K >= 0.
*
*  AF      (input) REAL array, dimension (LDA,N)
*          Details of the QR factorization of an m-by-n matrix, as
*          returnedby SGEQRF. See SGEQRF for further details.
*
*  C       (workspace) REAL array, dimension (LDA,N)
*
*  CC      (workspace) REAL array, dimension (LDA,N)
*
*  Q       (workspace) REAL array, dimension (LDA,M)
*
*  LDA     (input) INTEGER
*          The leading dimension of the arrays AF, C, CC, and Q.
*
*  TAU     (input) REAL array, dimension (min(M,N))
*          The scalar factors of the elementary reflectors corresponding
*          to the QR factorization in AF.
*
*  WORK    (workspace) REAL array, dimension (LWORK)
*
*  LWORK   (input) INTEGER
*          The length of WORK.  LWORK must be at least M, and should be
*          M*NB, where NB is the blocksize for this environment.
*
*  RWORK   (workspace) REAL array, dimension (M)
*
*  RESULT  (output) REAL array, dimension (4)
*          The test ratios compare two techniques for multiplying a
*          random matrix C by an m-by-m orthogonal matrix Q.
*          RESULT(1) = norm( Q*C - Q*C )  / ( M * norm(C) * EPS )
*          RESULT(2) = norm( C*Q - C*Q )  / ( M * norm(C) * EPS )
*          RESULT(3) = norm( Q'*C - Q'*C )/ ( M * norm(C) * EPS )
*          RESULT(4) = norm( C*Q' - C*Q' )/ ( M * norm(C) * EPS )
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               one, zero
      parameter( one = 1.0e0 )
      parameter( zero = 0.0e+0 )
      REAL               rogue
      parameter( rogue = -1.0e+10 )
*     ..
*     .. Local Scalars ..
      CHARACTER          side, trans
      INTEGER            info, iside, itrans, j, mc, nc
      INTEGER            plasma_side, plasma_trans
      REAL               cnorm, eps, resid
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      REAL               slamch, slange
      EXTERNAL           lsame, slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, slacpy, slarnv, slaset, sorgqr, sormqr
*     ..
*     .. Local Arrays ..
      INTEGER            iseed( 4 )
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       srnamt
*     ..
*     .. Common blocks ..
      common             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseed / 1988, 1989, 1990, 1991 /
*     ..
*     .. Executable Statements ..
*
      eps = slamch( 'Epsilon' )
      work(1) = one
*
*     Copy the first k columns of the factorization to the array Q
*
      IF ( k.EQ.0 ) THEN
          CALL slaset( 'Full', m, m, rogue, rogue, q, lda )
      ELSE
          CALL slaset( 'Full', m, m, zero, one, q, lda )
      ENDIF
*
*     Generate the m-by-m matrix Q
*
      srnamt = 'SORGQR'
      CALL plasma_sorgqr( m, m, k, af, lda, t, q, lda, info )
*
      DO 30 iside = 1, 2
         IF( iside.EQ.1 ) THEN
            side = 'L'
            plasma_side = plasmaleft
            mc = m
            nc = n
         ELSE
            side = 'R'
            plasma_side = plasmaright
            mc = n
            nc = m
         END IF
*
*        Generate MC by NC matrix C
*
         DO 10 j = 1, nc
            CALL slarnv( 2, iseed, mc, c( 1, j ) )
   10    continue
         cnorm = slange( '1', mc, nc, c, lda, rwork )
         IF( cnorm.EQ.0.0 )
     $      cnorm = one
*
         DO 20 itrans = 1, 2
            IF( itrans.EQ.1 ) THEN
               trans = 'N'
               plasma_trans = plasmanotrans
            ELSE
               trans = 'T'
               plasma_trans = plasmatrans
            END IF
*
*           Copy C
*
            CALL slacpy( 'Full', mc, nc, c, lda, cc, lda )
*
*           Apply Q or Q' to C
*
            srnamt = 'SORMQR'
            CALL plasma_sormqr( plasma_side, plasma_trans, mc, nc, k, 
     $                          af, lda, t, cc, lda, info )
*
*           Form explicit product and subtract
*
            IF ( k.EQ.0 ) THEN
               CALL slaset( 'Full', m, m, zero, one, q, lda )
            ENDIF
            IF( lsame( side, 'L' ) ) THEN
               CALL sgemm( trans, 'No transpose', mc, nc, mc, -one, q,
     $                     lda, c, lda, one, cc, lda )
            ELSE
               CALL sgemm( 'No transpose', trans, mc, nc, nc, -one, c,
     $                     lda, q, lda, one, cc, lda )
            END IF
*
*           Compute error in the difference
*
            resid = slange( '1', mc, nc, cc, lda, rwork )
            result( ( iside-1 )*2+itrans ) = resid /
     $         ( REAL( MAX( 1, M ) )*cnorm*eps )
*
   20    continue
   30 continue
*
      return
*
*     End of SQRT03
*
      END