sqrt02.f

Go to the documentation of this file.

      SUBROUTINE sqrt02( M, N, K, A, AF, Q, R, LDA, T, WORK, LWORK,
     $                   rwork, result )
*
      include 'plasmaf.h'
*
*  -- LAPACK test routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      INTEGER            k, lda, lwork, m, n
      INTEGER            t(2)
*     ..
*     .. Array Arguments ..
      REAL               a( lda, * ), af( lda, * ), q( lda, * ),
     $                   r( lda, * ), result( * ), rwork( * ), 
     $                   work( lwork )
*     ..
*
*  Purpose
*  =======
*
*  SQRT02 tests SORGQR, which generates an m-by-n matrix Q with
*  orthonornmal columns that is defined as the product of k elementary
*  reflectors.
*
*  Given the QR factorization of an m-by-n matrix A, SQRT02 generates
*  the orthogonal matrix Q defined by the factorization of the first k
*  columns of A; it compares R(1:n,1:k) with Q(1:m,1:n)'*A(1:m,1:k),
*  and checks that the columns of Q are orthonormal.
*
*  Arguments
*  =========
*
*  M       (input) INTEGER
*          The number of rows of the matrix Q to be generated.  M >= 0.
*
*  N       (input) INTEGER
*          The number of columns of the matrix Q to be generated.
*          M >= N >= 0.
*
*  K       (input) INTEGER
*          The number of elementary reflectors whose product defines the
*          matrix Q. N >= K >= 0.
*
*  A       (input) REAL array, dimension (LDA,N)
*          The m-by-n matrix A which was factorized by SQRT01.
*
*  AF      (input) REAL array, dimension (LDA,N)
*          Details of the QR factorization of A, as returned by SGEQRF.
*          See SGEQRF for further details.
*
*  Q       (workspace) REAL array, dimension (LDA,N)
*
*  R       (workspace) REAL array, dimension (LDA,N)
*
*  LDA     (input) INTEGER
*          The leading dimension of the arrays A, AF, Q and R. LDA >= M.
*
*  TAU     (input) REAL array, dimension (N)
*          The scalar factors of the elementary reflectors corresponding
*          to the QR factorization in AF.
*
*  WORK    (workspace) REAL array, dimension (LWORK)
*
*  LWORK   (input) INTEGER
*          The dimension of the array WORK.
*
*  RWORK   (workspace) REAL array, dimension (M)
*
*  RESULT  (output) REAL array, dimension (2)
*          The test ratios:
*          RESULT(1) = norm( R - Q'*A ) / ( M * norm(A) * EPS )
*          RESULT(2) = norm( I - Q'*Q ) / ( M * EPS )
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      REAL               rogue
      parameter( rogue = -1.0e+10 )
*     ..
*     .. Local Scalars ..
      INTEGER            info
      REAL               anorm, eps, resid
*     ..
*     .. External Functions ..
      REAL               slamch, slange, slansy
      EXTERNAL           slamch, slange, slansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, slacpy, slaset, sorgqr, ssyrk
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       srnamt
*     ..
*     .. Common blocks ..
      common             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      eps = slamch( 'Epsilon' )
*
*     Copy the first k columns of the factorization to the array Q
*
      CALL slaset( 'Full', m, n, zero, one, q, lda )
*
*     Generate the first n columns of the matrix Q
*
      srnamt = 'SORGQR'
      CALL plasma_sorgqr( m, n, k, af, lda, t, q, lda, info )
*
*     Copy R(1:n,1:k)
*
      CALL slaset( 'Full', n, k, zero, zero, r, lda )
      CALL slacpy( 'Upper', n, k, af, lda, r, lda )
*
*     Compute R(1:n,1:k) - Q(1:m,1:n)' * A(1:m,1:k)
*
      CALL sgemm( 'Transpose', 'No transpose', n, k, m, -one, q, lda, a,
     $            lda, one, r, lda )
*
*     Compute norm( R - Q'*A ) / ( M * norm(A) * EPS ) .
*
      anorm = slange( '1', m, k, a, lda, rwork )
      resid = slange( '1', n, k, r, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / REAL( MAX( 1, M ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q'*Q
*
      CALL slaset( 'Full', n, n, zero, one, r, lda )
      CALL ssyrk( 'Upper', 'Transpose', n, m, -one, q, lda, one, r,
     $            lda )
*
*     Compute norm( I - Q'*Q ) / ( M * EPS ) .
*
      resid = slansy( '1', 'Upper', n, r, lda, rwork )
*
      result( 2 ) = ( resid / REAL( MAX( 1, M ) ) ) / eps
*
      return
*
*     End of SQRT02
*
      END