spot01.f

Go to the documentation of this file.

      SUBROUTINE spot01( UPLO, N, A, LDA, AFAC, LDAFAC, RWORK, RESID )
*
*  -- LAPACK test routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            lda, ldafac, n
      REAL               resid
*     ..
*     .. Array Arguments ..
      REAL               a( lda, * ), afac( ldafac, * ), rwork( * )
*     ..
*
*  Purpose
*  =======
*
*  SPOT01 reconstructs a symmetric positive definite matrix  A  from
*  its L*L' or U'*U factorization and computes the residual
*     norm( L*L' - A ) / ( N * norm(A) * EPS ) or
*     norm( U'*U - A ) / ( N * norm(A) * EPS ),
*  where EPS is the machine epsilon.
*
*  Arguments
*  ==========
*
*  UPLO    (input) CHARACTER*1
*          Specifies whether the upper or lower triangular part of the
*          symmetric matrix A is stored:
*          = 'U':  Upper triangular
*          = 'L':  Lower triangular
*
*  N       (input) INTEGER
*          The number of rows and columns of the matrix A.  N >= 0.
*
*  A       (input) REAL array, dimension (LDA,N)
*          The original symmetric matrix A.
*
*  LDA     (input) INTEGER
*          The leading dimension of the array A.  LDA >= max(1,N)
*
*  AFAC    (input/output) REAL array, dimension (LDAFAC,N)
*          On entry, the factor L or U from the L*L' or U'*U
*          factorization of A.
*          Overwritten with the reconstructed matrix, and then with the
*          difference L*L' - A (or U'*U - A).
*
*  LDAFAC  (input) INTEGER
*          The leading dimension of the array AFAC.  LDAFAC >= max(1,N).
*
*  RWORK   (workspace) REAL array, dimension (N)
*
*  RESID   (output) REAL
*          If UPLO = 'L', norm(L*L' - A) / ( N * norm(A) * EPS )
*          If UPLO = 'U', norm(U'*U - A) / ( N * norm(A) * EPS )
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j, k
      REAL               anorm, eps, t
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      REAL               sdot, slamch, slansy
      EXTERNAL           lsame, sdot, slamch, slansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           sscal, ssyr, strmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         resid = zero
         return
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = slamch( 'Epsilon' )
      anorm = slansy( '1', uplo, n, a, lda, rwork )
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         return
      END IF
*
*     Compute the product U'*U, overwriting U.
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 10 k = n, 1, -1
*
*           Compute the (K,K) element of the result.
*
            t = sdot( k, afac( 1, k ), 1, afac( 1, k ), 1 )
            afac( k, k ) = t
*
*           Compute the rest of column K.
*
            CALL strmv( 'Upper', 'Transpose', 'Non-unit', k-1, afac,
     $                  ldafac, afac( 1, k ), 1 )
*
   10    continue
*
*     Compute the product L*L', overwriting L.
*
      ELSE
         DO 20 k = n, 1, -1
*
*           Add a multiple of column K of the factor L to each of
*           columns K+1 through N.
*
            IF( k+1.LE.n )
     $         CALL ssyr( 'Lower', n-k, one, afac( k+1, k ), 1,
     $                    afac( k+1, k+1 ), ldafac )
*
*           Scale column K by the diagonal element.
*
            t = afac( k, k )
            CALL sscal( n-k+1, t, afac( k, k ), 1 )
*
   20    continue
      END IF
*
*     Compute the difference  L*L' - A (or U'*U - A).
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 40 j = 1, n
            DO 30 i = 1, j
               afac( i, j ) = afac( i, j ) - a( i, j )
   30       continue
   40    continue
      ELSE
         DO 60 j = 1, n
            DO 50 i = j, n
               afac( i, j ) = afac( i, j ) - a( i, j )
   50       continue
   60    continue
      END IF
*
*     Compute norm( L*U - A ) / ( N * norm(A) * EPS )
*
      resid = slansy( '1', uplo, n, afac, ldafac, rwork )
*
      resid = ( ( resid / REAL( N ) ) / anorm ) / eps
*
      return
*
*     End of SPOT01
*
      END