slqt01.f

Go to the documentation of this file.

      SUBROUTINE slqt01( M, N, A, AF, Q, L, LDA, T, WORK, LWORK,
     $                   rwork, result )
*
      include 'plasmaf.h'
*
*  -- LAPACK test routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      INTEGER            lda, lwork, m, n
      INTEGER            t( 2 )
*     ..
*     .. Array Arguments ..
      REAL               a( lda, * ), af( lda, * ), l( lda, * ),
     $                   q( lda, * ), result( * ), rwork( * ),
     $                   work( lwork )
*     ..
*
*  Purpose
*  =======
*
*  SLQT01 tests SGELQF, which computes the LQ factorization of an m-by-n
*  matrix A, and partially tests SORGLQ which forms the n-by-n
*  orthogonal matrix Q.
*
*  SLQT01 compares L with A*Q', and checks that Q is orthogonal.
*
*  Arguments
*  =========
*
*  M       (input) INTEGER
*          The number of rows of the matrix A.  M >= 0.
*
*  N       (input) INTEGER
*          The number of columns of the matrix A.  N >= 0.
*
*  A       (input) REAL array, dimension (LDA,N)
*          The m-by-n matrix A.
*
*  AF      (output) REAL array, dimension (LDA,N)
*          Details of the LQ factorization of A, as returned by SGELQF.
*          See SGELQF for further details.
*
*  Q       (output) REAL array, dimension (LDA,N)
*          The n-by-n orthogonal matrix Q.
*
*  L       (workspace) REAL array, dimension (LDA,max(M,N))
*
*  LDA     (input) INTEGER
*          The leading dimension of the arrays A, AF, Q and L.
*          LDA >= max(M,N).
*
*  TAU     (output) REAL array, dimension (min(M,N))
*          The scalar factors of the elementary reflectors, as returned
*          by SGELQF.
*
*  WORK    (workspace) REAL array, dimension (LWORK)
*
*  LWORK   (input) INTEGER
*          The dimension of the array WORK.
*
*  RWORK   (workspace) REAL array, dimension (max(M,N))
*
*  RESULT  (output) REAL array, dimension (2)
*          The test ratios:
*          RESULT(1) = norm( L - A*Q' ) / ( N * norm(A) * EPS )
*          RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      REAL               rogue
      parameter( rogue = -1.0e+10 )
*     ..
*     .. Local Scalars ..
      INTEGER            info, minmn
      REAL               anorm, eps, resid
*     ..
*     .. External Functions ..
      REAL               slamch, slange, slansy
      EXTERNAL           slamch, slange, slansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgelqf, sgemm, slacpy, slaset, sorglq, ssyrk
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       srnamt
*     ..
*     .. Common blocks ..
      common             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      minmn = min( m, n )
      eps = slamch( 'Epsilon' )
*
*     Copy the matrix A to the array AF.
*
      CALL slacpy( 'Full', m, n, a, lda, af, lda )
*
*     Factorize the matrix A in the array AF.
*
      srnamt = 'SGELQF'
      CALL plasma_sgelqf( m, n, af, lda, t, info )
*
*     Copy details of Q
*
      CALL slaset( 'Full', m, n, zero, one, q, lda )
*
*     Generate the n-by-n matrix Q
*
      srnamt = 'SORGLQ'
      CALL plasma_sorglq( m, n, minmn, af, lda, t, q, lda, info )
*
*     Copy L
*
      CALL slaset( 'Full', m, n, zero, zero, l, lda )
      CALL slacpy( 'Lower', m, n, af, lda, l, lda )
*
*     Compute L - A*Q'
*
      CALL sgemm( 'No transpose', 'Transpose', m, m, n, -one, a, lda, q,
     $            lda, one, l, lda )
*
*     Compute norm( L - Q'*A ) / ( N * norm(A) * EPS ) .
*
      anorm = slange( '1', m, n, a, lda, rwork )
      resid = slange( '1', m, m, l, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / REAL( MAX( 1, N ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL slaset( 'Full', m, m, zero, one, l, lda )
      CALL ssyrk( 'Upper', 'No transpose', m, n, one, q, lda, -one, l,
     $            lda )
*
*     Compute norm( I - Q*Q' ) / ( N * EPS ) .
*
      resid = slansy( '1', 'Upper', m, l, lda, rwork )
*
      result( 2 ) = ( resid / REAL( MAX( 1, M ) ) ) / eps
*
      return
*
*     End of SLQT01
*
      END