dqrt17.f

Go to the documentation of this file.

      DOUBLE PRECISION FUNCTION dqrt17( TRANS, IRESID, M, N, NRHS, A,
     $                 lda, x, ldx, b, ldb, c, work, lwork )
*
*  -- LAPACK test routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      CHARACTER          trans
      INTEGER            iresid, lda, ldb, ldx, lwork, m, n, nrhs
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   a( lda, * ), b( ldb, * ), c( ldb, * ),
     $                   work( lwork ), x( ldx, * )
*     ..
*
*  Purpose
*  =======
*
*  DQRT17 computes the ratio
*
*     || R'*op(A) ||/(||A||*alpha*max(M,N,NRHS)*eps)
*
*  where R = op(A)*X - B, op(A) is A or A', and
*
*     alpha = ||B|| if IRESID = 1 (zero-residual problem)
*     alpha = ||R|| if IRESID = 2 (otherwise).
*
*  Arguments
*  =========
*
*  TRANS   (input) CHARACTER*1
*          Specifies whether or not the transpose of A is used.
*          = 'N':  No transpose, op(A) = A.
*          = 'T':  Transpose, op(A) = A'.
*
*  IRESID  (input) INTEGER
*          IRESID = 1 indicates zero-residual problem.
*          IRESID = 2 indicates non-zero residual.
*
*  M       (input) INTEGER
*          The number of rows of the matrix A.
*          If TRANS = 'N', the number of rows of the matrix B.
*          If TRANS = 'T', the number of rows of the matrix X.
*
*  N       (input) INTEGER
*          The number of columns of the matrix  A.
*          If TRANS = 'N', the number of rows of the matrix X.
*          If TRANS = 'T', the number of rows of the matrix B.
*
*  NRHS    (input) INTEGER
*          The number of columns of the matrices X and B.
*
*  A       (input) DOUBLE PRECISION array, dimension (LDA,N)
*          The m-by-n matrix A.
*
*  LDA     (input) INTEGER
*          The leading dimension of the array A. LDA >= M.
*
*  X       (input) DOUBLE PRECISION array, dimension (LDX,NRHS)
*          If TRANS = 'N', the n-by-nrhs matrix X.
*          If TRANS = 'T', the m-by-nrhs matrix X.
*
*  LDX     (input) INTEGER
*          The leading dimension of the array X.
*          If TRANS = 'N', LDX >= N.
*          If TRANS = 'T', LDX >= M.
*
*  B       (input) DOUBLE PRECISION array, dimension (LDB,NRHS)
*          If TRANS = 'N', the m-by-nrhs matrix B.
*          If TRANS = 'T', the n-by-nrhs matrix B.
*
*  LDB     (input) INTEGER
*          The leading dimension of the array B.
*          If TRANS = 'N', LDB >= M.
*          If TRANS = 'T', LDB >= N.
*
*  C       (workspace) DOUBLE PRECISION array, dimension (LDB,NRHS)
*
*  WORK    (workspace) DOUBLE PRECISION array, dimension (LWORK)
*
*  LWORK   (input) INTEGER
*          The length of the array WORK.  LWORK >= NRHS*(M+N).
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            info, iscl, ncols, nrows
      DOUBLE PRECISION   bignum, err, norma, normb, normrs, normx,
     $                   smlnum
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   rwork( 1 )
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      DOUBLE PRECISION   dlamch, dlange
      EXTERNAL           lsame, dlamch, dlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm, dlacpy, dlascl, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max
*     ..
*     .. Executable Statements ..
*
      dqrt17 = zero
*
      IF( lsame( trans, 'N' ) ) THEN
         nrows = m
         ncols = n
      ELSE IF( lsame( trans, 'T' ) ) THEN
         nrows = n
         ncols = m
      ELSE
         CALL xerbla( 'DQRT17', 1 )
         return
      END IF
*
      IF( lwork.LT.ncols*nrhs ) THEN
         CALL xerbla( 'DQRT17', 13 )
         return
      END IF
*
      IF( m.LE.0 .OR. n.LE.0 .OR. nrhs.LE.0 ) THEN
         return
      END IF
*
      norma = dlange( 'One-norm', m, n, a, lda, rwork )
      smlnum = dlamch( 'Safe minimum' ) / dlamch( 'Precision' )
      bignum = one / smlnum
      iscl = 0
*
*     compute residual and scale it
*
      CALL dlacpy( 'All', nrows, nrhs, b, ldb, c, ldb )
      CALL dgemm( trans, 'No transpose', nrows, nrhs, ncols, -one, a,
     $            lda, x, ldx, one, c, ldb )
      normrs = dlange( 'Max', nrows, nrhs, c, ldb, rwork )
      IF( normrs.GT.smlnum ) THEN
         iscl = 1
         CALL dlascl( 'General', 0, 0, normrs, one, nrows, nrhs, c, ldb,
     $                info )
      END IF
*
*     compute R'*A
*
      CALL dgemm( 'Transpose', trans, nrhs, ncols, nrows, one, c, ldb,
     $            a, lda, zero, work, nrhs )
*
*     compute and properly scale error
*
      err = dlange( 'One-norm', nrhs, ncols, work, nrhs, rwork )
      IF( norma.NE.zero )
     $   err = err / norma
*
      IF( iscl.EQ.1 )
     $   err = err*normrs
*
      IF( iresid.EQ.1 ) THEN
         normb = dlange( 'One-norm', nrows, nrhs, b, ldb, rwork )
         IF( normb.NE.zero )
     $      err = err / normb
      ELSE
         normx = dlange( 'One-norm', ncols, nrhs, x, ldx, rwork )
         IF( normx.NE.zero )
     $      err = err / normx
      END IF
*
      dqrt17 = err / ( dlamch( 'Epsilon' )*dble( max( m, n, nrhs ) ) )
      return
*
*     End of DQRT17
*
      END