cqrt01.f

Go to the documentation of this file.

      SUBROUTINE cqrt01( M, N, A, AF, Q, R, LDA, T, WORK, LWORK,
     $                   rwork, result )
*
      include 'plasmaf.h'
*
*  -- LAPACK test routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      INTEGER            lda, lwork, m, n
      INTEGER            t( 2 )
*     ..
*     .. Array Arguments ..
      REAL               result( * ), rwork( * )
      COMPLEX            a( lda, * ), af( lda, * ), q( lda, * ),
     $                   r( lda, * ),  work( lwork )
*     ..
*
*  Purpose
*  =======
*
*  CQRT01 tests CGEQRF, which computes the QR factorization of an m-by-n
*  matrix A, and partially tests CUNGQR which forms the m-by-m
*  orthogonal matrix Q.
*
*  CQRT01 compares R with Q'*A, and checks that Q is orthogonal.
*
*  Arguments
*  =========
*
*  M       (input) INTEGER
*          The number of rows of the matrix A.  M >= 0.
*
*  N       (input) INTEGER
*          The number of columns of the matrix A.  N >= 0.
*
*  A       (input) COMPLEX array, dimension (LDA,N)
*          The m-by-n matrix A.
*
*  AF      (output) COMPLEX array, dimension (LDA,N)
*          Details of the QR factorization of A, as returned by CGEQRF.
*          See CGEQRF for further details.
*
*  Q       (output) COMPLEX array, dimension (LDA,M)
*          The m-by-m orthogonal matrix Q.
*
*  R       (workspace) COMPLEX array, dimension (LDA,max(M,N))
*
*  LDA     (input) INTEGER
*          The leading dimension of the arrays A, AF, Q and R.
*          LDA >= max(M,N).
*
*  TAU     (output) COMPLEX array, dimension (min(M,N))
*          The scalar factors of the elementary reflectors, as returned
*          by CGEQRF.
*
*  WORK    (workspace) COMPLEX array, dimension (LWORK)
*
*  LWORK   (input) INTEGER
*          The dimension of the array WORK.
*
*  RWORK   (workspace) REAL array, dimension (M)
*
*  RESULT  (output) REAL array, dimension (2)
*          The test ratios:
*          RESULT(1) = norm( R - Q'*A ) / ( M * norm(A) * EPS )
*          RESULT(2) = norm( I - Q'*Q ) / ( M * EPS )
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            rogue
      parameter( rogue = ( -1.0e+10, -1.0e+10 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            info, minmn
      REAL               anorm, eps, resid
*     ..
*     .. External Functions ..
      REAL               clange, clansy, slamch
      EXTERNAL           clange, clansy, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, cgeqrf, cherk, clacpy, claset, cungqr
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, min, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       srnamt
*     ..
*     .. Common blocks ..
      common             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      minmn = min( m, n )
      eps = slamch( 'Epsilon' )
*
*     Copy the matrix A to the array AF.
*
      CALL clacpy( 'Full', m, n, a, lda, af, lda )
*
*     Factorize the matrix A in the array AF.
*
      srnamt = 'CGEQRF'
      CALL plasma_cgeqrf( m, n, af, lda, t, info )
*
*     Copy details of Q
*
      CALL claset( 'Full', m, n, cmplx(zero), cmplx(one), q, lda )
*
*     Generate the m-by-m matrix Q
*
      srnamt = 'CUNGQR'
      CALL plasma_cungqr( m, n, minmn, af, lda, t, q, lda, info )
*
*     Copy R
*
      CALL claset( 'Full', n, n, cmplx( zero ), cmplx( zero ), r, lda )
      CALL clacpy( 'Upper', n, n, af, lda, r, lda )
*
*     Compute R - Q'*A
*
      CALL cgemm( 'Conjugate transpose', 'No transpose', n, n, m,
     $            cmplx( -one ), q, lda, a, lda, cmplx( one ), r, lda )
*
*     Compute norm( R - Q'*A ) / ( M * norm(A) * EPS ) .
*
      anorm = clange( '1', m, n, a, lda, rwork )
      resid = clange( '1', n, n, r, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / REAL( MAX( 1, M ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q'*Q
*
      CALL claset( 'Full', n, n, cmplx( zero ), cmplx( one ), r, lda )
      CALL cherk( 'Upper', 'Conjugate transpose', n, m, one, q, lda,
     $            -one, r, lda )
*
*     Compute norm( I - Q'*Q ) / ( M * EPS ) .
*
      resid = clansy( '1', 'Upper', n, r, lda, rwork )
*
      result( 2 ) = ( resid / REAL( MAX( 1, N ) ) ) / eps
*
      return
*
*     End of CQRT01
*
      END