cpot01.f

Go to the documentation of this file.

      SUBROUTINE cpot01( UPLO, N, A, LDA, AFAC, LDAFAC, RWORK, RESID )
*
*  -- LAPACK test routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            lda, ldafac, n
      REAL               resid
*     ..
*     .. Array Arguments ..
      REAL               rwork( * )
      COMPLEX            a( lda, * ), afac( ldafac, * )
*     ..
*
*  Purpose
*  =======
*
*  CPOT01 reconstructs a Hermitian positive definite matrix  A  from
*  its L*L' or U'*U factorization and computes the residual
*     norm( L*L' - A ) / ( N * norm(A) * EPS ) or
*     norm( U'*U - A ) / ( N * norm(A) * EPS ),
*  where EPS is the machine epsilon, L' is the conjugate transpose of L,
*  and U' is the conjugate transpose of U.
*
*  Arguments
*  ==========
*
*  UPLO    (input) CHARACTER*1
*          Specifies whether the upper or lower triangular part of the
*          Hermitian matrix A is stored:
*          = 'U':  Upper triangular
*          = 'L':  Lower triangular
*
*  N       (input) INTEGER
*          The number of rows and columns of the matrix A.  N >= 0.
*
*  A       (input) COMPLEX array, dimension (LDA,N)
*          The original Hermitian matrix A.
*
*  LDA     (input) INTEGER
*          The leading dimension of the array A.  LDA >= max(1,N)
*
*  AFAC    (input/output) COMPLEX array, dimension (LDAFAC,N)
*          On entry, the factor L or U from the L*L' or U'*U
*          factorization of A.
*          Overwritten with the reconstructed matrix, and then with the
*          difference L*L' - A (or U'*U - A).
*
*  LDAFAC  (input) INTEGER
*          The leading dimension of the array AFAC.  LDAFAC >= max(1,N).
*
*  RWORK   (workspace) REAL array, dimension (N)
*
*  RESID   (output) REAL
*          If UPLO = 'L', norm(L*L' - A) / ( N * norm(A) * EPS )
*          If UPLO = 'U', norm(U'*U - A) / ( N * norm(A) * EPS )
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j, k
      REAL               anorm, eps, tr
      COMPLEX            tc
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      REAL               clanhe, slamch
      COMPLEX            cdotc
      EXTERNAL           lsame, clanhe, slamch, cdotc
*     ..
*     .. External Subroutines ..
      EXTERNAL           cher, cscal, ctrmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          aimag, real
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         resid = zero
         return
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = slamch( 'Epsilon' )
      anorm = clanhe( '1', uplo, n, a, lda, rwork )
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         return
      END IF
*
*     Check the imaginary parts of the diagonal elements and return with
*     an error code if any are nonzero.
*
      DO 10 j = 1, n
         IF( aimag( afac( j, j ) ).NE.zero ) THEN
            resid = one / eps
            return
         END IF
   10 continue
*
*     Compute the product U'*U, overwriting U.
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 20 k = n, 1, -1
*
*           Compute the (K,K) element of the result.
*
            tr = cdotc( k, afac( 1, k ), 1, afac( 1, k ), 1 )
            afac( k, k ) = tr
*
*           Compute the rest of column K.
*
            CALL ctrmv( 'Upper', 'Conjugate', 'Non-unit', k-1, afac,
     $                  ldafac, afac( 1, k ), 1 )
*
   20    continue
*
*     Compute the product L*L', overwriting L.
*
      ELSE
         DO 30 k = n, 1, -1
*
*           Add a multiple of column K of the factor L to each of
*           columns K+1 through N.
*
            IF( k+1.LE.n )
     $         CALL cher( 'Lower', n-k, one, afac( k+1, k ), 1,
     $                    afac( k+1, k+1 ), ldafac )
*
*           Scale column K by the diagonal element.
*
            tc = afac( k, k )
            CALL cscal( n-k+1, tc, afac( k, k ), 1 )
*
   30    continue
      END IF
*
*     Compute the difference  L*L' - A (or U'*U - A).
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 50 j = 1, n
            DO 40 i = 1, j - 1
               afac( i, j ) = afac( i, j ) - a( i, j )
   40       continue
            afac( j, j ) = afac( j, j ) - REAL( A( J, J ) )
   50    continue
      ELSE
         DO 70 j = 1, n
            afac( j, j ) = afac( j, j ) - REAL( A( J, J ) )
            DO 60 i = j + 1, n
               afac( i, j ) = afac( i, j ) - a( i, j )
   60       continue
   70    continue
      END IF
*
*     Compute norm( L*U - A ) / ( N * norm(A) * EPS )
*
      resid = clanhe( '1', uplo, n, afac, ldafac, rwork )
*
      resid = ( ( resid / REAL( N ) ) / anorm ) / eps
*
      return
*
*     End of CPOT01
*
      END