clqt02.f

Go to the documentation of this file.

      SUBROUTINE clqt02( M, N, K, A, AF, Q, L, LDA, T, WORK, LWORK,
     $                   rwork, result )
*
      include 'plasmaf.h'
*
*  -- LAPACK test routine (version 3.1) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      INTEGER            k, lda, lwork, m, n
      INTEGER            t( 2 )
*     ..
*     .. Array Arguments ..
      REAL               result( * ), rwork( * )
      COMPLEX            a( lda, * ), af( lda, * ), l( lda, * ),
     $                   q( lda, * ), work( lwork )
*     ..
*
*  Purpose
*  =======
*
*  CLQT02 tests CUNGLQ, which generates an m-by-n matrix Q with
*  orthonornmal rows that is defined as the product of k elementary
*  reflectors.
*
*  Given the LQ factorization of an m-by-n matrix A, CLQT02 generates
*  the orthogonal matrix Q defined by the factorization of the first k
*  rows of A; it compares L(1:k,1:m) with A(1:k,1:n)*Q(1:m,1:n)', and
*  checks that the rows of Q are orthonormal.
*
*  Arguments
*  =========
*
*  M       (input) INTEGER
*          The number of rows of the matrix Q to be generated.  M >= 0.
*
*  N       (input) INTEGER
*          The number of columns of the matrix Q to be generated.
*          N >= M >= 0.
*
*  K       (input) INTEGER
*          The number of elementary reflectors whose product defines the
*          matrix Q. M >= K >= 0.
*
*  A       (input) COMPLEX array, dimension (LDA,N)
*          The m-by-n matrix A which was factorized by CLQT01.
*
*  AF      (input) COMPLEX array, dimension (LDA,N)
*          Details of the LQ factorization of A, as returned by CGELQF.
*          See CGELQF for further details.
*
*  Q       (workspace) COMPLEX array, dimension (LDA,N)
*
*  L       (workspace) COMPLEX array, dimension (LDA,M)
*
*  LDA     (input) INTEGER
*          The leading dimension of the arrays A, AF, Q and L. LDA >= N.
*
*  TAU     (input) COMPLEX array, dimension (M)
*          The scalar factors of the elementary reflectors corresponding
*          to the LQ factorization in AF.
*
*  WORK    (workspace) COMPLEX array, dimension (LWORK)
*
*  LWORK   (input) INTEGER
*          The dimension of the array WORK.
*
*  RWORK   (workspace) REAL array, dimension (M)
*
*  RESULT  (output) REAL array, dimension (2)
*          The test ratios:
*          RESULT(1) = norm( L - A*Q' ) / ( N * norm(A) * EPS )
*          RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            rogue
      parameter( rogue = ( -1.0e+10, -1.0e+10 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            info
      REAL               anorm, eps, resid
*     ..
*     .. External Functions ..
      REAL               clange, clansy, slamch
      EXTERNAL           clange, clansy, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, cherk, clacpy, claset, cunglq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       srnamt
*     ..
*     .. Common blocks ..
      common             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      eps = slamch( 'Epsilon' )
*
*     Copy the first k rows of the factorization to the array Q
*
      CALL claset( 'Full', m, n, cmplx( zero ), cmplx( one ), q, lda )
*
*     Generate the first n columns of the matrix Q
*
      srnamt = 'CUNGLQ'
      CALL plasma_cunglq( m, n, k, af, lda, t, q, lda, info )
*
*     Copy L(1:k,1:m)
*
      CALL claset( 'Full', k, m, cmplx( zero ), cmplx( zero ), l, lda )
      CALL clacpy( 'Lower', k, m, af, lda, l, lda )
*
*     Compute L(1:k,1:m) - A(1:k,1:n) * Q(1:m,1:n)'
*
      CALL cgemm( 'No transpose', 'Conjugate transpose', k, m, n,
     $            cmplx( -one ), a, lda, q, lda, cmplx( one ), l, lda )
*
*     Compute norm( L - A*Q' ) / ( N * norm(A) * EPS ) .
*
      anorm = clange( '1', k, n, a, lda, rwork )
      resid = clange( '1', k, m, l, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / REAL( MAX( 1, N ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL claset( 'Full', m, m, cmplx( zero ), cmplx( one ), l, lda )
      CALL cherk( 'Upper', 'No transpose', m, n, -one, q, lda, one, l,
     $            lda )
*
*     Compute norm( I - Q*Q' ) / ( N * EPS ) .
*
      resid = clansy( '1', 'Upper', m, l, lda, rwork )
*
      result( 2 ) = ( resid / REAL( MAX( 1, N ) ) ) / eps
*
      return
*
*     End of CLQT02
*
      END