clartg.f

Go to the documentation of this file.

      SUBROUTINE clartg( F, G, CS, SN, R )
*
*  -- LAPACK auxiliary routine (version 3.2) --
*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
*     November 2006
*
*     .. Scalar Arguments ..
      REAL               cs
      COMPLEX            f, g, r, sn
*     ..
*
*  Purpose
*  =======
*
*  CLARTG generates a plane rotation so that
*
*     [  CS  SN  ]     [ F ]     [ R ]
*     [  __      ]  .  [   ]  =  [   ]   where CS**2 + |SN|**2 = 1.
*     [ -SN  CS  ]     [ G ]     [ 0 ]
*
*  This is a faster version of the BLAS1 routine CROTG, except for
*  the following differences:
*     F and G are unchanged on return.
*     If G=0, then CS=1 and SN=0.
*     If F=0, then CS=0 and SN is chosen so that R is real.
*
*  Arguments
*  =========
*
*  F       (input) COMPLEX
*          The first component of vector to be rotated.
*
*  G       (input) COMPLEX
*          The second component of vector to be rotated.
*
*  CS      (output) REAL
*          The cosine of the rotation.
*
*  SN      (output) COMPLEX
*          The sine of the rotation.
*
*  R       (output) COMPLEX
*          The nonzero component of the rotated vector.
*
*  Further Details
*  ======= =======
*
*  3-5-96 - Modified with a new algorithm by W. Kahan and J. Demmel
*
*  This version has a few statements commented out for thread safety
*  (machine parameters are computed on each entry). 10 feb 03, SJH.
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               two, one, zero
      parameter( two = 2.0e+0, one = 1.0e+0, zero = 0.0e+0 )
      COMPLEX            czero
      parameter( czero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
*     LOGICAL            FIRST
      INTEGER            count, i
      REAL               d, di, dr, eps, f2, f2s, g2, g2s, safmin,
     $                   safmn2, safmx2, scale
      COMPLEX            ff, fs, gs
*     ..
*     .. External Functions ..
      REAL               slamch, slapy2
      EXTERNAL           slamch, slapy2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, cmplx, conjg, int, log, max, REAL,
     $                   sqrt
*     ..
*     .. Statement Functions ..
      REAL               abs1, abssq
*     ..
*     .. Save statement ..
*     SAVE               FIRST, SAFMX2, SAFMIN, SAFMN2
*     ..
*     .. Data statements ..
*     DATA               FIRST / .TRUE. /
*     ..
*     .. Statement Function definitions ..
      abs1( ff ) = max( abs( REAL( FF ) ), abs( aimag( ff ) ) )
      abssq( ff ) = REAL( ff )**2 + aimag( ff )**2
*     ..
*     .. Executable Statements ..
*
*     IF( FIRST ) THEN
         safmin = slamch( 'S' )
         eps = slamch( 'E' )
         safmn2 = slamch( 'B' )**int( log( safmin / eps ) /
     $            log( slamch( 'B' ) ) / two )
         safmx2 = one / safmn2
*        FIRST = .FALSE.
*     END IF
      scale = max( abs1( f ), abs1( g ) )
      fs = f
      gs = g
      count = 0
      IF( scale.GE.safmx2 ) THEN
   10    continue
         count = count + 1
         fs = fs*safmn2
         gs = gs*safmn2
         scale = scale*safmn2
         IF( scale.GE.safmx2 )
     $      go to 10
      ELSE IF( scale.LE.safmn2 ) THEN
         IF( g.EQ.czero ) THEN
            cs = one
            sn = czero
            r = f
            return
         END IF
   20    continue
         count = count - 1
         fs = fs*safmx2
         gs = gs*safmx2
         scale = scale*safmx2
         IF( scale.LE.safmn2 )
     $      go to 20
      END IF
      f2 = abssq( fs )
      g2 = abssq( gs )
      IF( f2.LE.max( g2, one )*safmin ) THEN
*
*        This is a rare case: F is very small.
*
         IF( f.EQ.czero ) THEN
            cs = zero
            r = slapy2( REAL( G ), aimag( g ) )
*           Do complex/real division explicitly with two real divisions
            d = slapy2( REAL( GS ), aimag( gs ) )
            sn = cmplx( REAL( GS ) / d, -aimag( gs ) / d )
            return
         END IF
         f2s = slapy2( REAL( FS ), aimag( fs ) )
*        G2 and G2S are accurate
*        G2 is at least SAFMIN, and G2S is at least SAFMN2
         g2s = sqrt( g2 )
*        Error in CS from underflow in F2S is at most
*        UNFL / SAFMN2 .lt. sqrt(UNFL*EPS) .lt. EPS
*        If MAX(G2,ONE)=G2, then F2 .lt. G2*SAFMIN,
*        and so CS .lt. sqrt(SAFMIN)
*        If MAX(G2,ONE)=ONE, then F2 .lt. SAFMIN
*        and so CS .lt. sqrt(SAFMIN)/SAFMN2 = sqrt(EPS)
*        Therefore, CS = F2S/G2S / sqrt( 1 + (F2S/G2S)**2 ) = F2S/G2S
         cs = f2s / g2s
*        Make sure abs(FF) = 1
*        Do complex/real division explicitly with 2 real divisions
         IF( abs1( f ).GT.one ) THEN
            d = slapy2( REAL( F ), aimag( f ) )
            ff = cmplx( REAL( F ) / d, aimag( f ) / d )
         ELSE
            dr = safmx2*REAL( f )
            di = safmx2*aimag( f )
            d = slapy2( dr, di )
            ff = cmplx( dr / d, di / d )
         END IF
         sn = ff*cmplx( REAL( GS ) / g2s, -aimag( gs ) / g2s )
         r = cs*f + sn*g
      ELSE
*
*        This is the most common case.
*        Neither F2 nor F2/G2 are less than SAFMIN
*        F2S cannot overflow, and it is accurate
*
         f2s = sqrt( one+g2 / f2 )
*        Do the F2S(real)*FS(complex) multiply with two real multiplies
         r = cmplx( f2s*REAL( FS ), f2s*aimag( fs ) )
         cs = one / f2s
         d = f2 + g2
*        Do complex/real division explicitly with two real divisions
         sn = cmplx( REAL( R ) / d, aimag( r ) / d )
         sn = sn*conjg( gs )
         IF( count.NE.0 ) THEN
            IF( count.GT.0 ) THEN
               DO 30 i = 1, count
                  r = r*safmx2
   30          continue
            ELSE
               DO 40 i = 1, -count
                  r = r*safmn2
   40          continue
            END IF
         END IF
      END IF
      return
*
*     End of CLARTG
*
      END